#! /usr/bin/perl -w
 
# Script to report on, and delete, email messages stored in mbox-like
# files. Reads a list of files on stdin, so can be used as:
# find . -name '*.emlx' -print | script
# Use -v for verbose output about each duplicate file.
# Use -q to supress the summary at the end.
# Use -d (with care :-) to delete duplicates.
 
# Usage:
#   $ find . -name '*.emlx' -print | ./duplicate.pl -v
 
use strict;
 
use vars qw($opt_d $opt_q $opt_v);
use Getopt::Std;
 
my %ids = ();
my $dups = 0;
my $unique = 0;
my $total = 0;
 
getopts('dqv');
 
foreach (<>) {
  chomp;
  my $file = $_;
  my $id = "";
  if (!open MBOX, $file) {
    print "Warning: can't open file $file: $!, skipping.\n";
    next;
  }
  while (<MBOX>) {
    if (/^Message-ID: (<[^>]+>)/i) {
      $id = $1;
      if ($ids{$1}) {
        print "File $file is a duplicate of $ids{$1}" if ($opt_v);
        if ($opt_d) {
          unlink $file;
          print ", deleted" if ($opt_v);
        }
        print ".\n" if ($opt_v);
        $dups++;
      }
      else {
        $ids{$1} = $file;
        $unique++;
      }
      last;
    }
    elsif (/^$/) {
      if (!$id) {
        print "Warning: no Message-ID: header in file $file, skipping.\n"; 
      }
      close MBOX;
      last;
    }
  }
}
 
$total = $dups + $unique;
print "Summary: $total messages, $unique unique and $dups duplicates.\n"
if (!$opt_q);
exit 0;