tabled.clj

(defmacro tabled
  "Macro for defining a tabled goal. Prefer ^:tabled with the 
  defne/a/u forms over using this directly."
  [args & grest]
  (let [uuid (symbol (str "tabled-" (UUID/randomUUID)))]
    `(fn ~uuid [~@args]
       (let [argv# ~args]
         (fn [a#]
           (let [key#    (-reify a# argv#)
                 tables# (:ts a#)
                 tables# (if-not (contains? @tables# ~uuid)
                           (swap! tables#
                             (fn [v#]
                               (if (contains? v# ~uuid)
                                 v#
                                 (assoc v# ~uuid (atom {})))))
                           @tables#)
                 table#  (get tables# ~uuid)
                 cache#  (get @table# key#)]
             (if (nil? cache#)
               (let [cache# (atom #{})]
                 (swap! table# assoc key# cache#)
                 ((fresh []
                    ~@grest
                    (master argv# cache#)) a#))
               (reuse a# argv# cache# nil nil))))))))