gistfile1.clj

;; fixed indenting

(fn my-count [coll]
  (let [my-count-plus (fn my-count-plus [coll accumulator]
                        (let [r (rest coll)]
                          (cond
                           (= '() coll) accumulator
                           :else (my-count-plus r (+ 1 accumulator)))))]
    (my-count-plus coll 0)))

;; fixing newlines too

(fn my-count [coll]
  (let [my-count-plus (fn my-count-plus [coll accumulator]
                        (let [r (rest coll)]
                          (cond (= '() coll) accumulator
                                :else (my-count-plus r (+ 1 accumulator)))))]
    (my-count-plus coll 0)))

;; letfn instead of let..fn

(fn my-count [coll]
  (letfn [(my-count-plus [coll accumulator]
            (let [r (rest coll)]
              (cond (= '() coll) accumulator
                    :else (my-count-plus r (+ 1 accumulator)))))]
    (my-count-plus coll 0)))

;; if instead of cond

(fn my-count [coll]
  (letfn [(my-count-plus [coll accumulator]
            (let [r (rest coll)]
              (if (= '() coll)
                accumulator
                (my-count-plus r (+ 1 accumulator)))))]
    (my-count-plus coll 0)))

;; seq/nil? instead of =/()

(fn my-count [coll]
  (letfn [(my-count-plus [coll accumulator]
            (let [r (rest coll)]
              (if (seq coll)
                (my-count-plus r (+ 1 accumulator))
                accumulator)))]
    (my-count-plus coll 0)))

;; destructuring instead of rest

(fn my-count [coll]
  (letfn [(my-count-plus [coll accumulator]
            (if-let [[_ & r] (seq coll)]
              (my-count-plus r (+ 1 accumulator))
              accumulator))]
    (my-count-plus coll 0)))

;; loop/recur instead of a named inner fn

(fn my-count [coll]
  (loop [coll coll, accumulator 0]
    (if-let [[_ & r] (seq coll)]
      (recur r (+ 1 accumulator))
      accumulator)))