*scratch*.txt

{ config, pkgs, ... }:
let
  vterm-src = pkgs.fetchFromGitHub {
    owner = "akermu";
    repo = "emacs-libvterm";
    rev = "99511023cfc5bb524e157914fe943ca450b89942";
    sha256 = "136h31bkdiqsdm6vgkb4566qzh090cgikjnny47gwqy6xyz5w2c0";
  };
  emacs-custom = (pkgs.stable1903.emacs.override {
    imagemagick = pkgs.unstable.imagemagickBig;
    srcRepo = true;
    withXwidgets = true;
  }).overrideAttrs (old: rec {
    name = "emacs-${version}${versionModifier}";
    version = "27.0.50";
    versionModifier = "-git";
    src = pkgs.fetchFromGitHub {
      owner = "emacs-mirror";
      repo = "emacs";
      rev = "0a5212b99666b9ba0543a62cdbb12ee0685820f3";
      sha256 = "038kasdll0332vdpyc29xlkdj801sivz3ssnyz0dqr3gcavpk5yv";
    };
    patches = [ ];
  });
  emacs-overrides = (self: super: rec {
    emacs-libvterm = super.emacs-libvterm.overrideAttrs (attrs: {
      src = vterm-src;
      buildInputs = attrs.buildInputs ++ (with pkgs; [ git curl ]);
    });
  });
  custom-emacs =
    ((pkgs.stable1903.emacsPackagesNgGen emacs-custom).overrideScope'
    emacs-overrides);
  custom-emacs-and-packages = custom-emacs.emacsWithPackages
    (p: with p; [ pdf-tools proof-general emacs-libvterm ]);
in {
  environment.systemPackages = [ custom-emacs-and-packages ];
}