app-build.gradle

apply plugin: 'com.android.application'

repositories {
    mavenCentral()
}

android {
    compileSdkVersion 20
    buildToolsVersion "20.0.0"

    defaultConfig {
        minSdkVersion 16
        targetSdkVersion 20
        versionCode 1
        versionName "1.0.0"
    }

    if (project.hasProperty('production_key_store')
            && project.hasProperty('production_key_alias')
            && project.hasProperty('production_key_store_password')
            && project.hasProperty('production_key_alias_password')) {
        signingConfigs {
            production {
                storeFile file(project.properties.production_key_store)
                storePassword project.properties.production_key_store_password
                keyAlias project.properties.production_key_alias
                keyPassword project.properties.production_key_alias_password
            }
        }

        buildTypes {
            release {
                signingConfig signingConfigs.production
                runProguard true
                proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.txt'
            }
        }
    }

    buildTypes {
        debug {
            applicationIdSuffix ".debug"
        }
    }
}

dependencies {
    compile 'com.android.support:support-v4:20.0.0'
}