Splitting Headache

script.txt

title Splitting Headache [movement prototype]
author Alan Hazelden
homepage www.draknek.org

========
OBJECTS
========

Background 
GREEN  

Wall 
BROWN

Player 
Blue   

Crate 
Orange

WeakCrate
Orange
00000
0...0
0...0
0...0
00000

Current
red

Blocked
red

SpawnWeakCrate
red

=======
LEGEND
=======

. = Background
# = Wall
P = Player
* = Crate

Pushable = Crate or WeakCrate
Blocking = Wall or Blocked
Something = Wall or Crate or WeakCrate

=======
SOUNDS
=======

================
COLLISIONLAYERS
================

Background
Player, Wall, Crate, WeakCrate
Blocked, Current
SpawnWeakCrate

======
RULES     
======     

[ >  Player | Pushable ] -> [  >  Player | > Pushable  ]

startloop
[ > Pushable | stationary Pushable ] -> [ > Pushable | > Pushable ]

[ > Pushable | stationary Something ] -> [ > Pushable > Current | Something ]

(we've hit something solid)

(check for dead-end)

[ Wall | perpendicular WeakCrate Current | Wall ] -> [ Wall | | Wall ]
[ Wall | perpendicular Crate Current | Wall ] -> [ Wall | Crate | Wall ]

(check for corner)

[ Wall | perpendicular Pushable Current | no Wall ] -> [ Wall | > Pushable | ]
[ Something | perpendicular Pushable Current | no Something ] -> [ Something | > Pushable | ]
[ Crate | perpendicular Pushable Current | WeakCrate ] -> [ Crate | > Pushable | > WeakCrate ]

(check for split)

[ no Something | perpendicular WeakCrate Current | no Something ] -> [ | | ]
[ no Something | perpendicular Crate Current | no Something ] -> [ SpawnWeakCrate | | SpawnWeakCrate ]
[ WeakCrate | perpendicular WeakCrate Current | WeakCrate ] -> [ WeakCrate | | WeakCrate ]
[ WeakCrate | perpendicular Crate Current | WeakCrate ] -> [ < WeakCrate SpawnWeakCrate | | > WeakCrate SpawnWeakCrate ]

endloop

[ Blocked ] -> []
[ Current ] -> []

[ > Pushable | no Something ] -> [ | Pushable ]

[ SpawnWeakCrate no Something ] -> [ WeakCrate ]

==============
WINCONDITIONS
==============

=======     
LEVELS
=======

#########
#.......#
#.*.*.#.#
#.....#.#
#.*...#.#
###.p.#.#
###.....#
#########

Splitting Headache

Play this game by pasting the script in http://www.puzzlescript.net/editor.html