Buque.psc

Proceso Buque

	Definir contenedor_mayor Como caracter
	Definir peso_mayor Como entero
	
	Definir contenedor_menor Como caracter	
	Definir peso_menor Como entero
	
	Definir contenedores_puerto1 Como entero
	Definir contenedores_puerto2 Como entero
	Definir contenedores_puerto3 Como entero
	Definir peso_puerto1 Como entero
	Definir peso_puerto2 Como entero
	Definir peso_puerto3 Como entero
	
	// inicializa variables
	peso_mayor <- 0
	peso_menor <- 1000000 
	
	peso_puerto1 <- 0
	peso_puerto2 <- 0
	peso_puerto3 <- 0
	contenedores_puerto1 <- 0
	contenedores_puerto2 <- 0
	contenedores_puerto3 <- 0
	
	Escribir "Introduce los datos siguientes datos para cada contenedor del buque:"
	Escribir "	- Código de contenedor (Texto)"
	Escribir "	- Peso en Kg (de 1 a 1.000.000)"
	Escribir "	- Puerto destino (del 1 al 3)"
	Escribir "Para terminar pulse Intro dejando los campos vacíos."
	
	// entrada de datos inicial
	Escribir "(código, peso, puerto)"
	Leer contenedor, peso, puerto
	
	Mientras contenedor <> '' //contenedor vacío termina bucle
		// 1) calcula máximo
		Si peso > peso_mayor
			peso_mayor <- peso
			contenedor_mayor <- contenedor
		FinSi
		
		// 2) calcula máximo
		Si peso < peso_menor
			peso_menor <-peso
			contenedor_menor <- contenedor
		FinSi
		
		// 3) calcula pesos y cuenta por puerto
		Si puerto = 1
			peso_puerto1 <- peso_puerto1 + peso
			contenedores_puerto1 <- contenedores_puerto1 +1
		FinSi
		Si puerto = 2
			peso_puerto2 <- peso_puerto2 + peso
			contenedores_puerto2 <- contenedores_puerto2 +1
		FinSi
		Si puerto = 3
			peso_puerto3 <- peso_puerto3 + peso
			contenedores_puerto3 <- contenedores_puerto3 +1
		FinSi
		
		// entrada de datos otra vez
		Escribir "(código, peso, puerto)"
		Leer contenedor, peso, puerto
	FinMientras 
	
	// Sumario final
	Escribir "Contenedor mayor ",contenedor_mayor," pesa ",peso_mayor," kg."
	Escribir "Contenedor menor ",contenedor_menor," pesa ",peso_menor," kg."
	Escribir "Puerto 1 recibe ",contenedores_puerto1," contenedores que pesan ",peso_puerto1," kg."
	Escribir "Puerto 2 recibe ",contenedores_puerto2," contenedores que pesan ",peso_puerto2," kg."
	Escribir "Puerto 3 recibe ",contenedores_puerto3," contenedores que pesan ",peso_puerto3," kg."
FinProceso