Fernflower Deployment build.gradle

build.gradle

apply plugin: 'java'
apply plugin: 'maven-publish'

version = 382 + (System.getenv('BUILD_NUMBER') ?: project.ext.properties.buildNumber ?: 0).toInteger()
group = 'net.minecraftforge' //put it under us for now, because this is a unofficial mirrior
archivesBaseName = 'fernflower'
 
sourceCompatibility = '1.8'
targetCompatibility = '1.8'

sourceSets {
    main.java.srcDirs = ['src']
    test.java.srcDirs = ['test']
}
repositories {
    mavenCentral()
}
configurations {
    deployerJars
}

dependencies {
    testCompile 'junit:junit:4.12'
    testCompile 'org.hamcrest:hamcrest-core:1.3'
    testCompile 'org.assertj:assertj-core:3.6.1'
}

compileJava.options.encoding = 'utf-8'
compileJava.options.deprecation = true

jar.manifest {
    attributes 'Main-Class' : 'org.jetbrains.java.decompiler.main.decompiler.ConsoleDecompiler'
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact jar
        }
    }
    repositories {
        maven {
            if (project.hasProperty('forgeMavenPassword')) {
                credentials {
                    username project.properties.forgeMavenUser
                    password project.properties.forgeMavenPassword
                }
                url 'https://files.minecraftforge.net/maven/manage/upload'
            } else {
                url 'file://' + rootProject.file('repo').getAbsolutePath()
            }
        }
    }
}