persistent-postgresql case insensitive text

gistfile1.txt

-- First enable citext in psql: CREATE EXTENSION IF NOT EXISTS citext;

-- Create Model/CustomTypes.hs

{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE OverloadedStrings #-}
{-# OPTIONS_GHC -fno-warn-orphans #-}

module Model.CustomTypes where

import           Data.CaseInsensitive  (CI)
import qualified Data.CaseInsensitive as CI
import Data.Text (Text)
import qualified Data.Text as T
import Database.Persist.Sql
import qualified Data.Aeson as J
import Data.Aeson (ToJSON, FromJSON)
import qualified Data.Text.Encoding as TE

instance PersistField (CI Text) where
  toPersistValue ciText = PersistDbSpecific $ TE.encodeUtf8 (CI.original ciText)
  fromPersistValue (PersistDbSpecific bs) = Right $ CI.mk (TE.decodeUtf8 bs)
  fromPersistValue x = Left $ T.pack $ "Expected PersistDbSpecific, received: " ++ show x

instance PersistFieldSql (CI Text) where
  sqlType _ = SqlOther "citext"

instance (ToJSON (CI Text)) where
  toJSON a = J.String (CI.original a)

instance (FromJSON (CI Text)) where
  parseJSON (J.String text) = pure $ CI.mk text
  parseJSON v          = fail $ "Expected String, encountered " ++ (show v)
  

-- In Model.hs

import Data.CaseInsensitive  (CI)
import Model.CustomTypes ()

-- In models

Comment json -- Adding "json" causes ToJSON and FromJSON instances to be derived.
    message Text
    insensitive (CI Text)
    userId UserId Maybe
    deriving Eq
    deriving Show