package for llvm lnt

default.nix

{ python3, fetchFromGitHub, lib, lit }:


let
  packageOverrides = self: super: {
    sqlalchemy = super.sqlalchemy.overridePythonAttrs (oldAttrs: rec {
      version = "1.2.19";
      src = super.fetchPypi {
        pname = "SQLAlchemy";
        inherit version;
        sha256 = "sha256-W7LE/CvMNEetRXFsZlgeq5gsAH3PklSCSY2HM/hvF8c=";
      };
      doCheck = false;
    });
  };
  py = python3.override {
    # Put packageOverrides at the start so they are applied after defaultOverrides
    inherit packageOverrides;
  };
in py.pkgs.buildPythonApplication {
  pname = "lnt";
  version = "2021-12-14";

  src = fetchFromGitHub {
    owner = "llvm";
    repo = "llvm-lnt";
    rev = "016a4a7b6b50b4935b23068f82da1f1e3edd951f";
    sha256 = "sha256-henDx6dGJ8TziGc+DFi7wrQJ7s1DBXpHZ0eIPSQ8c5o=";
  };

  propagatedBuildInputs = with py.pkgs; [
    psycopg2
    sqlalchemy
    gunicorn
    progressbar2
    wtforms
    flask
    flask_wtf
    flask-restful
    six
    jinja2
    pytz
    itsdangerous
    click
    pyyaml
    requests
    future
    python-gnupg
    lit
    certifi
    werkzeug
  ];

  doCheck = false;

  postPatch = ''
    sed -i -e 's!"\(.*\)==.*"!"\1"!' setup.py
    sed -i -e '/typing/d' setup.py
  '';

  meta = with lib; {
    description = "LLVM Nightly Test Infrastructure";
    homepage = "https://llvm.org/docs/lnt/";
    license = licenses.apsl20;
    maintainers = with maintainers; [ mic92 ];
    platforms = platforms.unix;
  };
}