Demo for https://forum.starling-framework.org/topic/windows-multitouch-problem

TouchExperiments.as

package starling 
{
	import flash.utils.getTimer;
	import starling.display.Image;
	import starling.display.Quad;
	import starling.display.Sprite;
	import starling.events.Event;
	import starling.events.TouchEvent;
	import starling.events.Touch;
	import starling.textures.RenderTexture;
	
	/**
	 * ...
	 * @author Daniel Sperl
	 */
	public class TouchExperiments extends Sprite 
	{
		private var _background:Image;
		private var _brush:Quad;
		private var _renderTexture:RenderTexture;
 
		public function TouchExperiments()
		{
			super();
			addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		public function start():void
		{
		}
 
		private function init(e:Event):void
		{
			_brush = new Quad(5, 5)
			_renderTexture = new RenderTexture(stage.stageWidth, stage.stageHeight);
			_background = new Image(_renderTexture);
			addChild(_background);
			
			removeEventListener(Event.ADDED_TO_STAGE, init);
			addEventListener(TouchEvent.TOUCH, onTouch);
		}
 
		private function onTouch(e:TouchEvent):void
		{
			var time:int = getTimer();
			var touches:Vector.<Touch> = e.getTouches(this);
 
			_renderTexture.drawBundled(function():void
			{
				for (var i:int = 0; i < touches.length ; i++)
			    {
					//trace(time, touches.length, touches[i].phase);
					var touch:Touch = touches[i];
					
					_brush.x = touch.globalX;
					_brush.y = touch.globalY;
					_brush.color = Math.random() * 0xffffff;
					_renderTexture.draw(_brush);
				}				
			});		
		}
	}
}