gistfile1.txt

_pkgname=AppImageLauncher
pkgname=appimagelauncher
pkgver=1.2.2
pkgrel=1
pkgdesc="A Helper application for running and integrating AppImages."
arch=('x86_64')
url="https://github.com/TheAssassin/AppImageLauncher"
license=('MIT')
depends=('binutils'
    'boost'
    'cairo'
    'desktop-file-utils'
    'fuse'
    'googletest'
    'libarchive'
    'libbsd'
    'qt5-base'
    'shared-mime-info')
makedepends=('git' 'cmake' 'wget' 'vim' 'qt5-tools')
source=("git+$url.git#tag=v$pkgver"
        "appimage-binfmt-remove.hook")
sha256sums=('SKIP'
            '5da5313af1d1f7bbc2861a954b8fdce6ddead6fc6d8d3dc56b974e793fb7c50a')

prepare() {
  cd $_pkgname
  git submodule update --init --recursive
}

build() {
  cd $_pkgname
  cmake . -DCMAKE_INSTALL_PREFIX:PATH=/usr/ -DUSE_SYSTEM_GTEST=ON -DUSE_SYSTEM_XZ=ON \
          -DUSE_SYSTEM_LIBARCHIVE=ON \
          -DTOOLS_PREFIX=/usr/lib/qt5/bin/lupdate
  make
}

package() {
  install -Dm644 -t $pkgdir/usr/share/libalpm/hooks *.hook

  cd $_pkgname
  # re-run CMake to populate list of library files to bundle
  cmake .
  make DESTDIR="$pkgdir" install
  install -Dm644 LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/LICENSE

  # fix lib location
  mv $pkgdir/usr/lib64/* $pkgdir/usr/lib/
  rm -rf $pkgdir/usr/lib64
}