Skip to content

Instantly share code, notes, and snippets.

@SpotlightKid

SpotlightKid/PKGBUILD.sh

Last active Jul 7, 2020
Embed
What would you like to do?
PKGBUILD for feature/cython-extension branch of jack_mixer git version
# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
_pkgname=jack_mixer
pkgname="${_pkgname}-git"
pkgver=13rc1.r360.e2f0c95
pkgrel=1
pkgdesc="A GTK based Jack audio mixer (git version)"
arch=('x86_64')
url="https://rdio.space/jackmixer/"
license=('GPL2')
groups=('pro-audio')
depends=('gcc-libs' 'hicolor-icon-theme' 'python-cairo' 'python-gobject' 'python-pyxdg')
makedepends=('cython' 'git' 'glib2' 'jack' 'meson' 'python-setuptools')
optdepends=('new-session-manager: NSM session management support')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${_pkgname}::git+https://github.com/SpotlightKid/jack_mixer.git#branch=feature/cython-extension")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
local ver="$(grep 'version=' setup.py | cut -d \" -f 2)"
echo "$ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
build() {
cd "${srcdir}/${_pkgname}"
if [[ -d builddir ]]; then
meson --reconfigure --prefix=/usr builddir
else
meson --prefix=/usr builddir
fi
meson compile -C builddir
python setup.py build
}
package() {
depends+=('libglib-2.0.so' 'libjack.so')
cd "${srcdir}/${_pkgname}"
python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
DESTDIR="${pkgdir}" meson install -C builddir
# Install documentation
install -Dm644 AUTHORS README NEWS -t "${pkgdir}/usr/share/doc/${pkgname}"
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
You can’t perform that action at this time.