Skip to content

Instantly share code, notes, and snippets.

Embed
What would you like to do?
Improved PKGBUILD for B.Schaffl
# Maintainer: Milkii Brewster <milkii on Freenode IRC>
# Contributor: Christopher Arndt <aur -at- chrisarndt -dot- de>
_name="BSchaffl"
_pkgname="${_name,,}.lv2"
_plugin_uri="https://www.jahnichen.de/plugins/lv2/${_name}"
pkgname="${_pkgname}-git"
pkgdesc="Pattern-controlled MIDI amp & time stretch plugin to produce shuffle / swing effects (git version)"
pkgver=0.3.r0.g2ca653c
pkgrel=1
arch=(x86_64)
url="https://github.com/sjaehn/BSchaffl"
license=('GPL3')
groups=('lv2-plugins' 'pro-audio')
depends=('cairo' 'gcc-libs' 'glibc' 'libx11')
makedepends=('git' 'lv2')
checkdepends=('lv2lint')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${_pkgname}::git+https://github.com/sjaehn/${_name}")
md5sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
( set -o pipefail
git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
build() {
cd "${srcdir}/${_pkgname}"
make
}
check() {
cd "${srcdir}/${_pkgname}"
echo lv2lint -Mpack -I "${_name}.lv2/" "${_plugin_uri}"
lv2lint -Mpack -I "${_name}.lv2/" "${_plugin_uri}"
}
package() {
cd "${srcdir}/${_pkgname}"
make PREFIX="/usr" DESTDIR="$pkgdir/" install
install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
# remove useless license file
find "${pkgdir}/usr/lib/" -type f -iname "*LICENSE*" -delete
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
You can’t perform that action at this time.