PKGBUILD for dexed release 0.9.3

PKGBUILD-dexed-0.9.3.sh

# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>

pkgname="dexed"
pkgver=0.9.3
pkgrel=1
pkgdesc="A software synth closely modelled on the Yamaha DX7"
arch=('i686' 'x86_64')
url="http://asb2m10.github.io/dexed/"
license=("GPL3")
groups=('vst-plugins')
depends=('alsa-lib' 'curl' 'hicolor-icon-theme' 'freetype2' 'libxinerama')
makedepends=('steinberg-vst36')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/asb2m10/dexed/archive/v${pkgver}.tar.gz")
md5sums=('ddaf4d31304ae7ecfc3b51f633477ff3')
changelog=ChangeLog


prepare() {
  cd "$srcdir/${pkgname}-${pkgver}"

  msg2 "Fixing VST3 SDK include paths in JUCE sources..."
  sed -i -e 's|public.sdk/source/vst2.x|vst36|g' \
    JuceLibraryCode/modules/juce_audio_plugin_client/VST/juce_VST_Wrapper.cpp
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}/Builds/Linux"

  export CXXFLAGS="${CXXFLAGS} -DHAVE_LROUND"
  make CONFIG=Release
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # install VST plugin
  install -Dm755 Builds/Linux/build/Dexed.so "${pkgdir}/usr/lib/vst/Dexed.so"
}

# vim:set ts=2 sw=2 et: