Converts rails checkboxes to bootstrap buttonsets.

rails-bootstrap-checkboxes.coffee

# Example: Weekday Selection
# #weekdays{:data => {:toggle => :checkboxes}}
#      %label Weekdays
#      - [:mon, :tue, :wed, :thu, :fri, :sat, :sun].each do |wday|
#        = f.label wday
#        = f.check_box wday

# Creates a bootstrap buttonset and hides the original checkboxes
#--------------------------------------------------------------
initializeCheckboxButtonsets: () ->
  jQuery('[data-toggle=checkboxes]').each () ->
    elem = jQuery(@)
    tag = jQuery('<div class="btn-group" data-toggle="buttons-checkbox"></div>')
    elem.find('input[type=checkbox]').each () ->
      checkbox = jQuery(@)
      label = elem.find("label[for=#{checkbox.attr('id')}]")

      #Create a button with the label's caption
      buttonClasses = "btn btn-primary checkbox-button"
      buttonClasses += " active" if checkbox.prop('checked')
      button = jQuery('<button type="button" class="' + buttonClasses + '">' + label.html() + '</button>')

      #Attach an onClick handler that toggles the checkbox
      jQuery(button).on 'click', () ->
        checkbox.prop('checked', !button.hasClass('active'))
      jQuery(tag).append(button)

      #Hide checkbox and label
      label.hide()
      checkbox.hide()
    elem.append(tag)