site-footer.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output indent="yes" method="xml"/>
  <xsl:strip-space elements="*"/>

  <!-- Variables -->
  <!-- ================================================== -->


  <!-- Templates -->
  <!-- ================================================== -->
  <xsl:template match="site-configuration">

    <xsl:apply-templates select="department-information"/>

    <ul class="no-bullet inline-list">
      <li><a href="//www.rochester.edu/">University of Rochester</a></li>
      <li><a href="//www.rochester.edu/college/">AS&amp;E</a></li>
      <li>
        <a>
          <xsl:attribute name="href">
            <xsl:value-of select="department-information/department-url"/>
          </xsl:attribute>
          <xsl:value-of select="department-information/department-abbr"/>
        </a>
      </li>
    </ul>
    <!-- this will be the same for every footer -->
    <ul class="no-bullet inline-list">
      <li><a href="//www.rochester.edu/accessibility.html">Accessiblity</a></li>
      <li><a href="//text.rochester.edu/tt/referrer">Text</a></li>
      <li><a href="//www.rochester.edu/college/webcomm/">Web Communications</a></li>
    </ul>
    <p class="copyright"><small>&#169; 2019. All rights reserved.</small></p>
  </xsl:template>

  <xsl:template match="department-information">
    <p class="department-name">
      <xsl:value-of select="department-name"/>
    </p>
    <address>
      <dl>
        <dt class="show-for-sr">Address</dt>
        <dd>
          <xsl:apply-templates select="department-address"/>
        </dd>
        <dt class="show-for-sr">Email</dt>
        <dd>
          <a>
            <xsl:attribute name="href">
              <xsl:text>mailto:</xsl:text><xsl:value-of select="department-email"/>
            </xsl:attribute>
            <xsl:value-of select="department-email"/>
          </a>
        </dd>
        <dt class="show-for-sr">Phone</dt>
        <dd>
          <a>
            <xsl:attribute name="href">
              <xsl:text>tel:</xsl:text><xsl:value-of select="translate(department-phone, '() -', '')" />
            </xsl:attribute>
            <xsl:value-of select="department-phone"/>
          </a>
        </dd>
      </dl>
    </address>
  </xsl:template>

  <!-- https://stackoverflow.com/a/3310019 -->
  <xsl:template match="department-address">
    <p>
      <xsl:apply-templates/>
    </p>
  </xsl:template>

  <xsl:template match="text()" name="add-break-tags">
    <xsl:param name="currentText" select="."/>
    <xsl:choose>
      <xsl:when test="not(contains($currentText, '&#10;'))">
        <xsl:copy-of select="$currentText"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="substring-before($currentText, '&#10;')"/>
        <br/>
        <xsl:call-template name="add-break-tags">
          <xsl:with-param name="currentText" select="substring-after($currentText, '&#10;')"/>
        </xsl:call-template>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>