Пометки в дереве

file.bsl

&НаКлиентеНаСервереБезКонтекста
Процедура УстановитьПометкуГруппы(Строка)
	
	ИтогоПометка = 0;
	Колво        = 0;
	
	Строки = Строка.ПолучитьЭлементы();
	Для каждого Строка1 из Строки Цикл
		
		Если Строка1.Пометка = 1 Тогда
			ИтогоПометка = ИтогоПометка + 1; 
		КонецЕсли;	
		
		Колво = Колво + 1;
		
	КонецЦикла;	
	
	Если ИтогоПометка = 0 Тогда
		Строка.Пометка = 0;
	ИначеЕсли ИтогоПометка = Колво Тогда
		Строка.Пометка = 1;
	Иначе
		Строка.Пометка = 2;
	КонецЕсли;	
	
КонецПроцедуры	

&НаКлиентеНаСервереБезКонтекста
Процедура УстановитьПометкуПодчиненных(Строка, Пометка)
	
	Строки = Строка.ПолучитьЭлементы();
	Для каждого Строка1 из Строки Цикл
		
		Строка1.Пометка = Пометка;
		УстановитьПометкуПодчиненных(Строка1, Пометка);
		
	КонецЦикла;	
	
КонецПроцедуры	

&НаКлиенте
Процедура ДеревоПометкаПриИзменении(Элемент)
	
	ТекСтрока = Элементы.Дерево.ТекущиеДанные;
	Если ТекСтрока.Пометка = 2 Тогда
		ТекСтрока.Пометка = 0;
	КонецЕсли;
	
	УстановитьПометкуПодчиненных(ТекСтрока, ТекСтрока.Пометка);
	
	Родитель = ТекСтрока.ПолучитьРодителя();
	Пока Родитель <> Неопределено Цикл
		УстановитьПометкуГруппы(Родитель);
		Родитель = Родитель.ПолучитьРодителя();
	КонецЦикла;
	
КонецПроцедуры

&НаКлиенте
Процедура ВклВсе(Команда)
	
	Для каждого Строка1 из Дерево.ПолучитьЭлементы() Цикл
		Строка1.Пометка = 1;
		УстановитьПометкуПодчиненных(Строка1, Строка1.Пометка)
	КонецЦикла;	
	
КонецПроцедуры

&НаКлиенте
Процедура ВыклВсе(Команда)
	
	Для каждого Строка1 из Дерево.ПолучитьЭлементы() Цикл
		Строка1.Пометка = 0;
		УстановитьПометкуПодчиненных(Строка1, Строка1.Пометка)
	КонецЦикла;	
	
КонецПроцедуры