Solution for https://github.com/jeanlaurent/secretSanta in core.logic

clug-2014-01-23-santa.clj

(ns cdl.santa
  (:refer-clojure :exclude [==])
  (:use [clojure.core.logic]))

;; https://github.com/jeanlaurent/secretSanta

(def data
   (partition 2 '[Walter White
                  Skyler White
                  Gustavo Fring
                  Saul Goodman
                  Jesse Pinkman
                  Henry Schrader
                  Marie Schrader]))

(defne oreo 
  "MMmmm COOOKIES" ;; I don't know how to name that one
  [x y z]
  ([a a a])
  ([a b a] (!= a b))
  ([b a a] (!= a b)))
  
(defne zipo
  "zipped = (map (partial vector) xl yl)"
  [xl yl zipped]
  ([xs ys ()] (oreo xs ys ()))
  ([[x . xs] [y . ys] [z . zs]]
     (== z [x y])
     (zipo xs ys zs)))

(defne ruleo [z]
  ([()])
  ([[[[_ x] [_ y]] . as]] ; extract names of the first pair
   (!= x y) 
   (ruleo as)))

(run 10  [couple]
     (fresh [result]
            (zipo data result couple)
            (permuteo data result)
            (ruleo couple)))

In fact, oreo is a materialized version of membero, so it's not really useful :

(defne zipo
  "zipped = (map (partial vector) xl yl)"
  [xl yl zipped]
  ([xs ys ()] (membero () [xs ys]))
  ([[x . xs] [y . ys] [z . zs]]
     (== z [x y])
     (zipo xs ys zs)))