Cleans portable flash drives from common flash drive viruses, and unhides files and directories.

Clean Flash Drive.bat

:: Author: Ali Essam (https://github.com/ali-essam)

echo off
echo Remember to run this script as Adminstrator
echo Make sure to put this batch in the root directory of the flash drive
echo Working dir: "%~dp0"
echo %~nx0
cd /d %~dp0
echo.

:: Config System32 Path for Win 7,8,8.1 x64
setlocal
SET PATH=%PATH%;%WINDIR%\System32

:r_und
:: Confirm Unhide Dirs
echo.
echo List Of Dirs:
for /F "delims=" %%X in ('dir /A:D /b') do echo "%%X"
echo.
set /P c=Unhide all directories[y/n]?
if /I "%c%" EQU "n" goto :r_unf

:: Unhide Directories
for /F "delims=" %%X in ('dir /A:D /b') do (attrib -s -h -r /d /s "%%X")

:r_unf
:: Confirm Unhide Files
echo.
echo List Of Files:
for /F "delims=" %%X in ('dir /A-D /b') do echo "%%X"
echo.
set /P c=Unhide all files[y/n]?
if /I "%c%" EQU "n" goto :r_rlnk

:: Unhide Files
for /F "delims=" %%X in ('dir /A-D /b') do (attrib -s -h -r /d /s "%%X")

:r_rlnk
:: Confirm Remove Shortcuts
echo.
echo List Of Shortcuts:
dir /b *.lnk
echo.
set /P c=Remove shortcuts[y/n]?
if /I "%c%" EQU "n" goto :r_rexe

:: Remove Shortcuts
del /F /Q *.lnk


:r_rexe
:: Confirm Remove EXEs
echo.
echo List Of EXEs:
dir /b *.exe
echo.
set /P c=Remove EXEs[y/n]?
if /I "%c%" EQU "n" goto :r_rsc

:: Remove EXEs
del /F /Q *.exe

:r_rsc
:: Confirm Remove Scripts
echo.
echo List Of Scripts(.vbs, .bat):
dir /b *.vbs *.bat
echo.
set /P c=Remove Scripts[y/n]?
if /I "%c%" EQU "n" goto :r_end

:: Remove Scripts
for /F "delims=" %%X in ('dir /b *.bat *.vbs') do (if "%%X" NEQ "%~nx0" (del /F /Q "%%X") )

:r_end
echo Finished

pause