Create a gist now

Instantly share code, notes, and snippets.

anonymous /SIMPL_Shift_2
Created May 11, 2014

SIMPL Interpreter for Arduino with shift register support
// SIMPL Shift 2
// A Serial Interpreted Minimal Programming Language
// Inspired by Txtzyme - by Ward Cunningham
// This version adds support for shift registers and stepper motors
// SIMPL tries to take you back to an age of computing when things were simple
// So it compiles in under 6K - leaving lots of room for other stuff
// SIMPL allows new words to be defined by preceding them with colon : (Like Forth)
// New words use CAPITALS - so 26 words are possible in the vocabulary
// Words A-F have been predefined as musical tones - but you can write over them
// A word can be a maximum of 48 characters long
// Type ? to get a list off all defined words
#define bufRead(addr) (*(unsigned char *)(addr))
#define bufWrite(addr, b) (*(unsigned char *)(addr) = (b))
unsigned char bite;
unsigned int x = 0;
unsigned int y = 0;
int len = 48;
// Define the I?O pins to be used with the shift registers
int sinPin = 5; // Serial input pin from 74HC165
int sclkPin = 6; // Clock pin to 74HC165
int loadPin = 7; // parallel load pin of 74HC165
int latchPin = 8; //Pin connected to ST_CP of 74HC595
int dataPin = 9; //Pin connected to DS of 74HC595
int clockPin = 10; //Pin connected to SH_CP of 74HC595
char array[26][48] = { // Define a 26 x 64 array for the colon definitions
{"6d75{1o708u0o708u}"},
{"9rP8rP12rP4rP6rP2rP3rP1rP"}, // A backward step on a stepper motor
{"6d91{1o585u0o585u}"},
{"6d100{1o532u0o532u}"},
{"6d110{1o484u0o484u}"},
{"1rP3rP2rP6rP4rP12rP8rP9rP"}, // A forward step on a stepper motor
{"6d133{1o484u0o484u}"},
{"_Hello World, and welcome to SIMPL_"},
{"5{ABC}"},
{" "},
{" "},
{" "},
{" "},
{" "},
{" "},
{"100m"}, // Time delay to see stepper motor action
};
int d = 5;
char name;
char* parray;
char buf[64];
char* addr;
void setup()
{
Serial.begin(115200);
pinMode(d,OUTPUT);
pinMode(loadPin, OUTPUT); // Set up the pins needed for the shift registers
pinMode(sclkPin, OUTPUT);
pinMode(sinPin, INPUT);
pinMode(latchPin, OUTPUT);
pinMode(clockPin, OUTPUT);
pinMode(dataPin, OUTPUT);
digitalWrite(sclkPin,HIGH); // initialise the clock HIGH
// delay(2000);
Serial.println("Type H for Welcome or ? for Help");
parray = &array[0][0]; // parray is the pointer to the first element
}
void loop() // The SIMPL interpreter is just the following 3 functions executed within a loop
{
txtRead(buf, 64); // Get the next character from the buffer
txtChk(buf); // check if it is a colon definition
txtEval(buf); // Evaluate the character and execute the code associated with it
}
void txtRead (char *p, byte n) {
byte i = 0;
while (i < (n-1)) {
while (!Serial.available());
char ch = Serial.read();
if (ch == '\r' || ch == '\n') break;
if (ch >= ' ' && ch <= '~') {
*p++ = ch;
i++;
}
}
*p = 0;
}
void txtChk (char *buf) { // Check if the text starts with a colon and if so store in temp[]
if (*buf == ':') {
char ch;
int i =0;
while ((ch = *buf++)){
if (ch == ':') {
Serial.println(*buf); // get the name from the first character
name = *buf ;
buf++;
}
bufWrite((parray + (len*(name-65) +i)),*buf);
i++;
}
}
}
void txtEval (char *buf) {
unsigned int k = 0;
char *loop;
char ch;
while ((ch = *buf++)) {
switch (ch) {
case '0': // Ennumerate it to a variable x if the characters are digits
case '1':
case '2':
case '3':
case '4':
case '5':
case '6':
case '7':
case '8':
case '9':
x = ch - '0';
while (*buf >= '0' && *buf <= '9') {
x = x*10 + (*buf++ - '0');
}
break;
case 'p': // Print out the value of x
Serial.println(x);
break;
case '=': // more familiar for maths
Serial.println(x);
break;
case 'd':
d = x;
break;
case 'A': // Point the interpreter to the array containing the words
case 'B':
case 'C':
case 'D':
case 'E':
case 'F':
case 'G':
case 'H':
case 'I':
case 'J':
case 'K':
case 'L':
case 'M':
case 'N':
case 'O':
case 'P':
case 'Q':
case 'R':
case 'S':
case 'T':
case 'U':
case 'V':
case 'W':
case 'X':
case 'Y':
case 'Z':
name = ch - 65;
addr = parray + (len*name);
txtEval(addr);
break;
case 'y':
y = x;
case '!': // store
y = x;
break;
case '@': // fetch
x = y;
break;
case '+': // Add
x = x+y;
break;
case '-': // Subtract
x = y-x;
break;
case '*': // Multiply
x = x*y;
break;
case '/': // Divide
x = y/x;
break;
case '?': // Print out all the RAM
parray = &array[0][0]; // reset parray to the pointer to the first element
for (int j = 0; j<26; j++) {
Serial.write(j+65); // print the caps word name
Serial.write(20); // space
for (int i=0; i<len; i++) {
bite = bufRead( parray + (j *len )+i); // read the array
Serial.write(bite); // print the character to the serial port
}
Serial.println();
}
for(int i = 0; i <11; i++) { // Print 12 free lines so it looks better on Arduino serial screen
Serial.println();
}
break;
case 'i':
x = digitalRead(d);
break;
case 'o':
digitalWrite(d, x%2);
break;
case 'm':
delay(x);
break;
case 'u':
delayMicroseconds(x);
break;
case '{':
k = x;
loop = buf;
while ((ch = *buf++) && ch != '}') {
}
case '}':
if (k) {
k--;
buf = loop;
}
break;
case 'k':
x = k;
break;
case '_':
while ((ch = *buf++) && ch != '_') {
Serial.print(ch);
}
Serial.println();
break;
case 's':
x = analogRead(x);
break;
case 'q': // Send an 8 bit byte to the shift register using shiftOut
PORTB &= ~_BV(0);
shiftOut(dataPin, clockPin, MSBFIRST, x); // shift out the bits:
PORTB |= _BV(0);
break;
case 'r': // Send an 16 bit byte to the shift register using shiftOut
PORTB &= ~_BV(0);
shiftOut(dataPin, clockPin, MSBFIRST, x>>8); // shift out the high bits:
shiftOut(dataPin, clockPin, MSBFIRST, x); // shift out the low bits:
PORTB |= _BV(0);
break;
case 't': // test the inputs from 74HC165 shift registers
// Read incoming word from 74HC165
digitalWrite(loadPin, LOW);
digitalWrite(loadPin, HIGH);
x = shiftIn(sinPin, sclkPin, MSBFIRST);
digitalWrite(sclkPin,HIGH);
break;
}
}
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment