PKGBUILD

PKGBUILD.txt

# $Id: PKGBUILD 63578 2012-02-05 11:57:36Z ibiru $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=gdal-oci
pkgver=1.9.2
pkgrel=1
pkgdesc="A translator library for raster geospatial data formats, with OCI support"
arch=('i686' 'x86_64')
url="http://www.gdal.org/"
license=('custom')
depends=('curl' 'geos' 'giflib' 'hdf5' 'libgeotiff' 'libjpeg' 'libpng' 'libtiff' 'netcdf'  'python2' 'python2-numpy' 'cfitsio' 'sqlite3' 'libmysqlclient' 'postgresql-libs' 'oracle-instantclient-basic' 'oracle-instantclient-sdk')
makedepends=('perl' 'swig')
optdepends=('postgresql: postgresql database support'
            'mysql: mysql database support'
            'perl:  perl binding support'
            'swig:  perl binding support')
options=('!libtool')
changelog=$pkgname.changelog
source=(http://download.osgeo.org/gdal/gdal-${pkgver}.tar.gz
        gdal-1.5.1-python-install.patch)
md5sums=('3f39db89f4710269b3a8bf94178e07aa'
         '81afc1c26d29cee84aadb6924fe33861')
build() {
  export CFLAGS="$CFLAGS -fno-strict-aliasing"

  echo $ORACLE_HOME
  echo $TNS_ADMIN

  # bug 23654
  export LDFLAGS="$LDFLAGS -Wl,--as-needed" 

  cd ${srcdir}/gdal-$pkgver
  patch -Np0 -i ${srcdir}/gdal-1.5.1-python-install.patch

# python2 fixes
  sed -i 's_python python1.5_python2 python python1.5_' configure
  for file in swig/python/{,osgeo/,samples/,scripts/}*.py; do
      sed -i 's_#!/usr/bin/env python_#!/usr/bin/env python2_' $file
  done

  ./configure --prefix=/usr --with-netcdf --with-libtiff --with-sqlite3 \
              --with-geotiff --with-mysql --with-python --without-libtool --with-curl \
              --with-hdf5 --with-perl --with-geos --with-png \
              --with-oci

# workaround for bug #13646
  sed -i 's/PY_HAVE_SETUPTOOLS=1/PY_HAVE_SETUPTOOLS=/g' ./GDALmake.opt
  sed -i 's/EXE_DEP_LIBS/KILL_EXE_DEP_LIBS/' apps/GNUmakefile
  install -d ${pkgdir}/usr/lib/python2.7/site-packages/

  make
}

package () {
  cd ${srcdir}/gdal-$pkgver

  make DESTDIR=${pkgdir} install

# install license
  install -D -m644 LICENSE.TXT ${pkgdir}/usr/share/licenses/gdal/LICENSE

#FS15477 clean up junks
  rm -f ${pkgdir}/usr/bin/*.dox
}