diamond thing

diamond.pde

// gif by david

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop(){
  popStyle();
  popMatrix();
}

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if(mousePressed)
        println(c);
    draw_();
  }
  
  else {
  for (int i=0; i<width*height; i++)
    for (int a=0; a<3; a++)
      result[i][a] = 0;

  c = 0;
  for (int sa=0; sa<samplesPerFrame; sa++) {
    t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
    draw_();
    loadPixels();
    for (int i=0; i<pixels.length; i++) {
      result[i][0] += pixels[i] >> 16 & 0xff;
      result[i][1] += pixels[i] >> 8 & 0xff;
      result[i][2] += pixels[i] & 0xff;
    }
  }

  loadPixels();
  for (int i=0; i<pixels.length; i++)
    pixels[i] = 0xff << 24 | 
      int(result[i][0]*1.0/samplesPerFrame) << 16 | 
      int(result[i][1]*1.0/samplesPerFrame) << 8 | 
      int(result[i][2]*1.0/samplesPerFrame);
  updatePixels();

  saveFrame("f###.gif");
  if (frameCount==numFrames)
    exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 420;        
float shutterAngle = .4;

boolean recording = false;

void setup() {
  size(540, 500, P3D);
  smooth(8);
  noStroke();
  colorMode(HSB, 1);
  result = new int[width*height][3];
  rectMode(CENTER);
  //stroke(.1);
  strokeWeight(2);
}


int N = 6;
int nt = 5;
float l = 180;

void gradBlock(float h1, float h2) {
  for (int i=0; i<N; i++) {
    pushMatrix();
    translate(0, 0, map(i, 0, N-1, -.5*l+.5*l/N, .5*l-.5*l/N));
    fill(map(i, 0, N-1, h1, h2)/float(nt), .9, .9);
    box(l, l, l/N-16);
    popMatrix();
  }
}

void draw_() {
  background(.1);
  pushMatrix();
  translate(width/2, height/2);
  rotateY(-PI*((nt*t)%1));
  rotateY(PI);
  rotate(QUARTER_PI);
  gradBlock(int(nt*t), int(nt*t)+.999999999);
  popMatrix();
  
  loadPixels();
  for(int i=0; i<width/2; i++){
    for(int j=0; j<height/2; j++){
      pixels[j*width + width-i] = pixels[j*width + i];
    }
  }
  updatePixels();
}