blocks.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 170;        
float shutterAngle = .3;

boolean recording = true;

void setup_() {
  size(640, 540, P3D);
  rectMode(CENTER);
  fill(32);
  noStroke();
}

float x, y, tt;
int N = 12;

color c1 = #FF3126, c3 = #0054E3, c2 = #FFCC20;

void boxo(float w, float h, float d) {
  fill(c1);
  pushMatrix();
  translate(0, 0, d/2);
  rect(0, 0, w, h);
  popMatrix();
  pushMatrix();
  translate(0, 0, -d/2);
  rect(0, 0, w, h);
  popMatrix();
  fill(c2);
  pushMatrix();
  translate(0, -h/2, 0);
  rotateX(HALF_PI);
  rect(0, 0, w, d);
  popMatrix();
  pushMatrix();
  translate(0, h/2, 0);
  rotateX(HALF_PI);
  rect(0, 0, w, d);
  popMatrix();
  fill(c3);
  pushMatrix();
  translate(-w/2, 0);
  rotateY(HALF_PI);
  rect(0, 0, d, h);
  popMatrix();
  pushMatrix();
  translate(w/2, 0);
  rotateY(HALF_PI);
  rect(0, 0, d, h);
  popMatrix();
  ortho();
}

float ph, th, ah;
float om;

void draw_() {
  background(c3); 
  pushMatrix();
  translate(width/2, height/2, -1000);
  scale(.6);
  rotateX(-atan(sqrt(.5)));
  rotateY(QUARTER_PI);
  for (int i=-N; i<=N; i++) {
    for (int j=-N; j<=N; j++) {
      randomSeed(12345+23456*i+34567*j+456789);
      th = random(TWO_PI);
      ph = random(TWO_PI);
      ah = random(TWO_PI);
      om = random(1, 5);
      tt = constrain(3.4*t - 0.23*dist(i,j,0,0),0,1);
      pushMatrix();
      translate(i*100,150*sq(1-tt),j*100);
      scale(tt);
      rotateZ(HALF_PI);
      rotateX(-ph);
      rotateY(-th);
      rotateZ(-ah);
      rotateX(PI*sq(1-tt));
      rotateZ(ah);
      rotateY(th);
      rotateX(ph);
      boxo(100, 100, 100);
      popMatrix();
    }
  }
  popMatrix();
}