flower — http://tmblr.co/ZOLwww1PS3fP2

gistfile1.pde

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 180;        
float shutterAngle = .7;

boolean recording = true;

void setup_() {
  size(500, 500, P3D);
  rectMode(CENTER);
  fill(255);
  noStroke();
  blendMode(EXCLUSION);
  smooth(8);
}

float x, y, tt;
int N = 5;
float l = 100;
float d, q, qq;

void draw_() {
  if (t<=.67) {
    q = map(t, 0, .67, 0, 1);
    q = ease(q, 3);
    qq = 0;
  } 
  else {
    q = 1;
    qq = map(t, .67, 1, 0, 1);
    qq = ease(qq, 3);
  }
  background(255); 
  pushMatrix();
  translate(width/2, height/2);
  for (int i=0; i<6; i++) {
    for (int a=0; a<4; a++) {
      pushMatrix();
      rotate((i-a*(1-qq)/4.0)*TWO_PI/6);
      d = 2*l*q;
      ellipse(l, 0, d, d);
      popMatrix();
    }
  }
  popMatrix();
}