swirler — http://tmblr.co/ZOLwww1QJ4n0e

gistfile1.pde

// by dave @ bees & bombs >:)

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    draw_();
  }
  
  else {
  for (int i=0; i<width*height; i++)
    for (int a=0; a<3; a++)
      result[i][a] = 0;

  for (int sa=0; sa<samplesPerFrame; sa++) {
    t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
    draw_();
    loadPixels();
    for (int i=0; i<pixels.length; i++) {
      result[i][0] += pixels[i] >> 16 & 0xff;
      result[i][1] += pixels[i] >> 8 & 0xff;
      result[i][2] += pixels[i] & 0xff;
    }
  }

  loadPixels();
  for (int i=0; i<pixels.length; i++)
    pixels[i] = 0xff << 24 | 
      int(result[i][0]*1.0/samplesPerFrame) << 16 | 
      int(result[i][1]*1.0/samplesPerFrame) << 8 | 
      int(result[i][2]*1.0/samplesPerFrame);
  updatePixels();

  saveFrame("f###.gif");
  if (frameCount==numFrames)
    exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 32;
int numFrames = 260;        
float shutterAngle = .6;

boolean recording = false;

void setup_() {
  size(500,500,P3D);
  smooth(8);
  strokeWeight(3);
  rectMode(CENTER);
  noFill();
}

int N = 1080;
float R = 130, r = 55, rr;
float th, ph, l = PI*1.4;
float ll = .002;
int n = 10;

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2);
  beginShape();
  for(int i=0; i<N; i++){
    th = TWO_PI*t + i*l/N;
    ph = n*th + 3*TWO_PI*t;
    rr = map(exp(-ll*(N-1-i)),1,exp(-ll*N),r,0);
    strokeWeight(map(exp(-.5*ll*(N-1-i)),1,exp(-.5*ll*N),5,.3));
    vertex(R*cos(th)+rr*cos(ph),R*sin(th)+rr*sin(ph));
  }
  endShape();
  popMatrix();
}