orbs.pde

// by davey w. @beesandbombs
// i put a little colour tint on it in photoshop

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if(mousePressed)
        println(c);
    draw_();
  }
  
  else {
  for (int i=0; i<width*height; i++)
    for (int a=0; a<3; a++)
      result[i][a] = 0;

  c = 0;
  for (int sa=0; sa<samplesPerFrame; sa++) {
    t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
    draw_();
    loadPixels();
    for (int i=0; i<pixels.length; i++) {
      result[i][0] += pixels[i] >> 16 & 0xff;
      result[i][1] += pixels[i] >> 8 & 0xff;
      result[i][2] += pixels[i] & 0xff;
    }
  }

  loadPixels();
  for (int i=0; i<pixels.length; i++)
    pixels[i] = 0xff << 24 | 
      int(result[i][0]*1.0/samplesPerFrame) << 16 | 
      int(result[i][1]*1.0/samplesPerFrame) << 8 | 
      int(result[i][2]*1.0/samplesPerFrame);
  updatePixels();

  saveFrame("g###.gif");
  if (frameCount==numFrames)
    exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 16;
int numFrames = 100;        
float shutterAngle = .6;

PImage cat;

boolean recording = false;

void setup_() {
  size(540,540,P3D);
  smooth(8);
  rectMode(CENTER);
  fill(32);
  noStroke();
  colorMode(HSB,1);
}

float x, y, z, tt;
int N = 60;
float th, ph;
float R = 140, r = 36, d = 22;

void draw_() {
  background(0); 
  pushMatrix();
  translate(width/2, height/2 - 20);
  rotateX(-.8);
  for(int i=0; i<N; i++){
    th = TWO_PI*(i-3*t)*3/N;
    ph = th/3 + TWO_PI*t;
    fill((ph/TWO_PI) % 1,1,1);
    
    x = (R+r*cos(ph))*cos(th);
    y = r*sin(ph);
    z = (R+r*cos(ph))*sin(th);
    
    pushMatrix();
    translate(x,y,z);
    sphere(map(cos(ph),-1,1,d*.75,d));
    popMatrix();
  }
  popMatrix();
}