dots

dots.pde

// source code for dots gif by dave "beesandbombs" whyte :)

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if(mousePressed)
        println(c);
    draw_();
  }
  
  else {
  for (int i=0; i<width*height; i++)
    for (int a=0; a<3; a++)
      result[i][a] = 0;

  c = 0;
  for (int sa=0; sa<samplesPerFrame; sa++) {
    t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
    draw_();
    loadPixels();
    for (int i=0; i<pixels.length; i++) {
      result[i][0] += pixels[i] >> 16 & 0xff;
      result[i][1] += pixels[i] >> 8 & 0xff;
      result[i][2] += pixels[i] & 0xff;
    }
  }

  loadPixels();
  for (int i=0; i<pixels.length; i++)
    pixels[i] = 0xff << 24 | 
      int(result[i][0]*1.0/samplesPerFrame) << 16 | 
      int(result[i][1]*1.0/samplesPerFrame) << 8 | 
      int(result[i][2]*1.0/samplesPerFrame);
  updatePixels();

  saveFrame("d###.gif");
  if (frameCount==numFrames)
    exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 360;        
float shutterAngle = .35;

boolean recording = false;

void setup() {
  size(800,600,P2D);
  result = new int[width*height][3];
  smooth(8);
  rectMode(CENTER);
  fill(32);
  noStroke();
  strokeWeight(1.3);
}

float x, y, tt;
int N = 12;
float l;

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, 160);
  for(int i=0; i<N; i++){
    l = map(i,-.75,N-1,0,320);
    stroke(32);
    noFill();
    arc(0,0,2*l,2*l,0,PI);
    fill(32);
    noStroke();
    pushMatrix();
    rotate(-HALF_PI*sin(TWO_PI*(N-i)*t));
    translate(0,l);
    ellipse(0,0,14,14);
    popMatrix();
    
  }
  popMatrix();
}