sphere.pde

/* 
 everything above the "//////" line is
 a motion blur hack -- use setup_() in
 place of setup() and draw_() in place
 of draw(). when 'recording' is set to
 false, mouseX controls time. if it is
 set to true, it exports frames as gif
 files -- i use 'gifsicle' to assemble
 the exported frames into animated gif 
*/

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 2;
int numFrames = 80;        
float shutterAngle = .5;

boolean recording = false;

void setup_() {
  size(540, 540, P3D);
  smooth(8);
  rectMode(CENTER);
  fill(32);
  noStroke();
}

float x, y, z, tt;
int N = 26;
float R = 220, r;
int n = 32;
float th;
float ph;

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2, - 150);
  rotateX(-.4);
  rotateY(-PI*t/N);
  for (int a=-1; a<n+1; a++) {
    th = lerp(-HALF_PI, HALF_PI, 1.0*(a+t)/n);
    y = R*sin(th);
    r = sqrt(R*R - y*y);
    for (int i=0; i<N; i++) {
      pushMatrix();
      ph = TWO_PI*(i+.5*((a+12)%2))/N;
      x = r*cos(ph);
      z = r*sin(ph);
      translate(x, y, z);
      fill(map(z,-r,r,210,36));
      if (-HALF_PI<=th && th<=HALF_PI)
        sphere(.032*r);
      popMatrix();
    }
  }
  popMatrix();
}