morning sketch flower sketch

flower.pde

// good luck 

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if(mousePressed)
        println(c);
    draw_();
  }
  
  else {
  for (int i=0; i<width*height; i++)
    for (int a=0; a<3; a++)
      result[i][a] = 0;

  c = 0;
  for (int sa=0; sa<samplesPerFrame; sa++) {
    t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
    draw_();
    loadPixels();
    for (int i=0; i<pixels.length; i++) {
      result[i][0] += pixels[i] >> 16 & 0xff;
      result[i][1] += pixels[i] >> 8 & 0xff;
      result[i][2] += pixels[i] & 0xff;
    }
  }

  loadPixels();
  for (int i=0; i<pixels.length; i++)
    pixels[i] = 0xff << 24 | 
      int(result[i][0]*1.0/samplesPerFrame) << 16 | 
      int(result[i][1]*1.0/samplesPerFrame) << 8 | 
      int(result[i][2]*1.0/samplesPerFrame);
  updatePixels();

  saveFrame("f###.gif");
  if (frameCount==numFrames)
    exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 12;
int numFrames = 144;        
float shutterAngle = 1;

boolean recording = false;

void setup_() {
  size(600,500,P3D);
  smooth(8);
  stroke(32);
  noFill();
}

float x, y, z;
int N = 900, n = 8;
float rm = 260, q, th, r;

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2 - 45, -100);
  rotateX(.78);
  beginShape();
  for(int i=0; i<N; i++){
    q = pow(i/float(N-1),.52);
    th = TWO_PI*n*q + TWO_PI*t;
    r = rm*q;
    z = q*40*cos(10.5*th + TWO_PI*1.5*t);
    strokeWeight(map(z,-40,40,1,5)*q);
    vertex(r*cos(th),r*sin(th), z);
  }
  endShape();
  popMatrix();
}