helix.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("t-###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 294;        
float shutterAngle = .6;

boolean recording = false;

void setup_() {
  size(540, 540, P3D);
  rectMode(CENTER);
  fill(32);
  smooth(8);
  noStroke();
}

float x, y, z, tt;
int N = 10, n = 160;
float q, r;

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2);
  for (int i=0; i<N; i++) {
    pushMatrix();
    rotateY(TWO_PI*i/N + PI*t);

    stroke(32);
    noFill();
    strokeWeight(1.25);
    beginShape(LINES);
    for (int a=0; a<n; a++) {
      q = a/float(n-1);
      y = lerp(-height*.65, height*.65, q);
      r = map(sin(PI*q), 0, 1, 150, 75);
      x = r*cos(TWO_PI*q);
      z = r*sin(TWO_PI*q);
      vertex(x, y, z);
    }
    endShape();

    fill(32);
    noStroke();
    q = (1.25*t + .5*i/float(N))%1;
    pushMatrix();
    y = lerp(-height*.65, height*.65, q);
    r = map(sin(PI*q), 0, 1, 150, 75);
    x = r*cos(TWO_PI*q);
    z = r*sin(TWO_PI*q);
    translate(x, y, z);
    sphere(6);
    popMatrix();
    q = (1.25*t + .5+.5*i/float(N))%1;
    pushMatrix();
    y = lerp(-height*.65, height*.65, q);
    r = map(sin(PI*q), 0, 1, 150, 75);
    x = r*cos(TWO_PI*q);
    z = r*sin(TWO_PI*q);
    translate(x, y, z);
    sphere(6);
    popMatrix();
    popMatrix();
  }
  popMatrix();
}