First attempt at De Bruijn sequence generator

de-bruijn.pl6

#! /usr/bin/env perl6

use v6;

proto sub de-bruijn ( \alphabet, Int $length ) {*}

multi sub de-bruijn ( Int $k, $length ) { samewith [^$k], $length }
multi sub de-bruijn ( Str $k, $length ) { samewith [$k.comb], $length }

multi sub de-bruijn ( @alphabet, $length ) {

  my @a = 0 xx @alphabet * $length;

  my @sequence;

  sub db ( $t, $p ) {
    if $t > $length {
      return if $length !%% $p;
      for 1 .. $p -> $j {
        @sequence.push: @alphabet[@a[$j]];
      }
      return;
    }

    @a[$t] = @a[$t-$p];
    db $t+1, $p;

    for @a[$t-$p]+1 ..^ @alphabet -> $j {
      @a[$t] = $j;
      db $t+1, $t;
    }
  }

  db 1, 1;

  return @sequence;
}

say de-bruijn 2, 3;
say de-bruijn 'abcd', 2;
say de-bruijn ['a','bb','ccc', 'dddd'], 3;

=finish

0 0 0 1 0 1 1 1

a a b a c a d b b c b d c c d d

a a a bb a a ccc a a dddd a bb bb a bb ccc a bb dddd a ccc bb a ccc ccc a ccc dddd a dddd bb a dddd ccc a dddd dddd bb bb bb ccc bb bb dddd bb ccc ccc bb ccc dddd bb dddd ccc bb dddd dddd ccc ccc ccc dddd ccc dddd dddd dddd

Translated from
https://gist.github.com/dwendt/5cc5223d4686d0e33209