Using assembly attributes to trigger code transformations

AssemblyAttributeTriggerSpike.boo

namespace Spikes

import Boo.Lang.PatternMatching
import Boo.Lang.Compiler
import Boo.Lang.Compiler.Ast
import Boo.Lang.Compiler.MetaProgramming

class EnableResponsePatternAttribute(AbstractAstAttribute):
  	override def Apply(node as Node):
		node.Accept(ResponseTransformer())
		
	class ResponseTransformer(DepthFirstTransformer):
		override def OnExpressionStatement(node as ExpressionStatement):
			match node.Expression:
				case [| $target = response |]:
					replacement = [|
						yield responseRef = Response()
						$target = responseRef.Value
					|]
					ReplaceCurrentNode replacement
				otherwise:
					pass
					
class Response:
	property Value

def spike():
	code = [|
		import Spikes
		
		def run():
			r = response
			print r
			
		for r in run():
			r.Value = "pong"
		
		[assembly: EnableResponsePattern]
	|]
	result = compile_(code, typeof(EnableResponsePatternAttribute).Assembly)
	#print code.ToCodeString()
	assembly = result.GeneratedAssembly
	assert assembly is not null
	assert assembly.EntryPoint is not null
	assembly.EntryPoint.Invoke(null, (null,))