aur PKGBUILD for gnome shell night theme switcher extension

PKGBUILD

# Maintainer: Igor Dyatlov <dyatlov.igor@protonmail.com>

pkgname=gnome-shell-extension-nightthemeswitcher
pkgver=79
pkgrel=1
pkgdesc="Automatically toggle your light and dark themes variants"
arch=('any')
url="https://gitlab.com/rmnvgr/nightthemeswitcher-gnome-shell-extension"
license=('GPL3')
groups=('gnome-shell-extensions')
depends=('gnome-shell>=1:46')
makedepends=('git' 'glib2' 'npm' 'meson')
checkdepends=('reuse' 'eslint')
source=("$pkgname-$pkgver.tar.gz::https://gitlab.com/rmnvgr/nightthemeswitcher-gnome-shell-extension/-/archive/79/nightthemeswitcher-gnome-shell-extension-$pkgver.tar.gz")
sha256sums=('d79d6970d6c623b30a5152a9bbc2baff88baa2e405b61cba9d9e8247616fd573')

build() {
  cd $srcdir/nightthemeswitcher-gnome-shell-extension-$pkgver
  export npm_config_cache="$srcdir/npm_cache"
  npm install

  arch-meson . build
  meson compile -C build
}

check() {
  cd $srcdir/nightthemeswitcher-gnome-shell-extension-$pkgver
  meson test -C build --print-errorlogs || :
}

package() {
  cd $srcdir/nightthemeswitcher-gnome-shell-extension-$pkgver
  meson install -C build --destdir "$pkgdir"
}