PKGBUILD.rodent

# Maintainer: Brian Bidulock <bidulock@openss7.org>
# Contributor: Anntoin Wilkinson <anntoin gmail com>
# Contributor: Iñigo Alvarez<alvarezviu@gmail.com>

pkgname=rodent
pkgver=5.2.8
pkgrel=1
pkgdesc="Lightweight, yet full of options filemanager, compatible with console commands"
arch=('i686' 'x86_64')
url="http://xffm.org/"
license=('GPL3')
makedepends=('pkg-config' 'intltool' 'librsvg')
depends=('librfm5' 'desktop-file-utils')
optdepends=('python2: for rfm-simple-agent')
install=$pkgname.install
source=(http://downloads.sourceforge.net/project/xffm/$pkgname/$pkgname-$pkgver.tar.bz2)
md5sums=('f94b5a81163a23045edf2d5e506949c6')

prepare()
{
  cd "$srcdir/$pkgname-$pkgver"
  sed -i 's/python/python2/' apps/rodent-fm/plugins/filesystem_user_space/rfm-simple-agent
}

build()
{
    cd "$srcdir/$pkgname-$pkgver"
    ./configure --prefix=/usr
    make
}

package()
{
    cd "$srcdir/$pkgname-$pkgver"
    make DESTDIR="${pkgdir}" install
}

rodent.install

post_install() {
  update-desktop-database -q usr/share/applications
  gtk-update-icon-cache usr/share/icons/hicolor
}
post_upgrade() {
  post_install
}
post_remove() {
  post_install
}