Temporary PKGBUILD to build coccinelle-git

gistfile1.txt

# PKGBUILD builds current coccinelle master, as the current coccinelle stable release is not buildable on ArchLinux anymore.
# Diff it against https://aur.archlinux.org/cgit/aur.git/commit/?h=coccinelle&id=540550d09c602fac376a87544833eda2a77e9647

# Maintainer: Omar Sandoval <osandov at osandov dot com>
# Contributor: Roger Zanoni <rogerzanoni@gmail.com>
# Contributor: Sylvain Henry <hsyl20@gmail.com>
# Contributor: Marti Raudsepp <marti@juffo.org>
# Contributor: Dan McGee <dpmcgee@gmail.com>
# Contributor: LeCrayonVert <sunrider@laposte.net>
# Contributor: Lukas Fleischer <archlinux@cryptocrack.de>
# Contributor: Vladimir Kirillov <proger@wilab.org.ua>

pkgname=coccinelle-git
pkgver=1.0.6.r418.7e4c6c8d
pkgrel=1
pkgdesc="Provides spatch program used to apply semantic patches"
arch=('i686' 'x86_64')
url="http://coccinelle.lip6.fr/"
license=('GPL2')
makedepends=('camlp4' 'ocaml' 'ocaml-findlib')
depends=('pcre' 'python')
optdepends=('ocaml: OCaml scripting feature'
            'ocaml-findlib: OCaml scripting feature')
options=('!strip')
source=('git+https://github.com/coccinelle/coccinelle.git')
md5sums=('SKIP')

pkgver() {
        cd "$srcdir/${pkgname%-git}"
        printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}

build() {
        cd "$srcdir/${pkgname%-git}"

  ./autogen
  ./configure --prefix=/usr
  make
}

package() {
        cd "$srcdir/${pkgname%-git}"

  make DESTDIR="$pkgdir/" MANDIR="/usr/share/man" install
}

# vim:set ts=2 sw=2 et: