swing

swing.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 120;        
float shutterAngle = .6;

boolean recording = false;

void setup() {
  size(900, 600, P3D);
  result = new int[width*height][3];
  rectMode(CENTER);
  noFill();
  strokeWeight(5);
  colorMode(HSB, 1);
}

int n = 60;
float qq;
float th;

void thing(float q, float hu) {
  beginShape();
  for (int i=0; i<n; i++) {
    qq = i/float(n-1);
    th = .25*cos(TWO_PI*q - PI/3*qq);
    y = lerp(0, height-120, qq);
    x = y*sin(th);
    y = y*cos(th);
    stroke((map(x, -100, 100, 0, 1)+hu+100)%1, 1, 1);
    vertex(x, y);
  }
  endShape();
}

float x, y, z, tt;
int N = 12;

void draw_() {
  background(0); 
  push();
  translate(width/2, 40);
  for (int i=-12; i<=12; i++) {
    push();
    translate(-60*i, 0);
    thing(t + .05*i,i);
    pop();
  }
  pop();
}

gif: https://twitter.com/beesandbombs/status/897920557588639744