arcs & triangles & circles

arcsTrisCircs.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

float c01(float g) {
  return constrain(g, 0, 1);
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 360;        
float shutterAngle = 1;

boolean recording = false;

void setup() {
  size(720, 720, P3D);
  pixelDensity(recording ? 1 : 2);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  fill(10);
  noStroke();
}

float x, y, z, tt;
int N = 12;
float r = 60;
float sp = 2*r*mn;
float ee = 3, v = 3, te;
color ORANGE = #ec973e;

void tri() {
  push();
  fill(ORANGE);
  beginShape();
  for (int i=0; i<3; i++)
    vertex(r*sin(TWO_PI*i/3), -r*cos(TWO_PI*i/3));
  endShape(CLOSE);
  pop();
}

void thing() {
  fill(10);
  for (int i=0; i<3; i++) {
    push();
    rotate(TWO_PI*i/3);
    arc(0, -r, r*mn*2, r*mn*2, HALF_PI-PI/6, HALF_PI+PI/6);
    pop();
  }
}


void draw_() {
  background(ORANGE);
  push();
  translate(width/2, height/2);
  if (t <= .5) {
    t = 2*t;
    for (int i=-N; i<=N; i++) {
      for (int j=-N; j<=N; j++) {
        x = i*sp;
        y = j*mn*sp;
        if (j%2 != 0)
          x += .5*sp;
        tt = c01(v*t - map(-y, -width*.55, width*.55, 0, v-1));
        te = ease(tt, ee);
        push();
        translate(x, y);
        translate(0, lerp(-sp*2/3.0*mn, 0, te));
        rotate(TWO_PI/6*te*(j%2 == 0 ? 1 : -1));
        thing();
        pop();
      }
    }
  }
  
  else {
    t = 2*t - 1;
    fill(10);
    for (int i=-N; i<=N; i++) {
      for (int j=-N; j<=N; j++) {
        x = i*sp;
        y = (j+2/3.0)*mn*sp;
        if (j%2 != 0)
          x += .5*sp;
        push();
        translate(x, y);
        ellipse(0, 0, 2*r*mn, 2*r*mn);
        pop();
      }
    }


    for (int i=-N; i<=N; i++) {
      for (int j=-N; j<=N; j++) {
        x = i*sp;
        y = (j-2/3.0)*mn*sp;
        if (j%2 != 0)
          x += .5*sp;

        tt = c01(v*t - map(-y, -width*.55, width*.55, 0, v-1));
        te = ease(tt, ee);
        push();
        translate(0, te*2/3.0*mn*sp);
        translate(x, y);
        rotate(TWO_PI/6*te*(j%2 == 0 ? 1 : -1));
        tri();
        pop();
      }
    }
  }
  pop();
}