wavy hexagon

wavyHexagon.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

float c01(float g) {
  return constrain(g, 0, 1);
}

void draw() {
  if (recording) {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  } else if (preview) {
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    t = (millis()/(20.0*numFrames))%1;
    draw_();
  } else {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 150;        
float shutterAngle = .6;

boolean recording = false, 
  preview = true;

void setup() {
  size(850, 750, P3D);
  smooth(8);  
  rectMode(CENTER);
  result = new int[width*height][3];
  stroke(32);
  noFill();
  strokeWeight(3.5);
  blendMode(NORMAL);
}

float x, y, z, tt;
float wavePhase;

void waveVertex(float x_, float y_) {
  vertex(x_ + 15*sin(TWO_PI*t - 0.03*y_ + wavePhase), y_);
}

int n;
void waveLine(float x1, float y1, float x2, float y2) {
  n = 2+ceil(0.1*dist(x1,y1,x2,y2));
  beginShape();
  for (int i=0; i<n; i++)
    waveVertex(map(i, 0, n-1, x1, x2), map(i, 0, n-1, y1, y2));
  endShape();
}

float r = 210, th, qq;

void hexx(){
  for (int i=0; i<6; i++) {
    th = TWO_PI*i/6;
    waveLine(-r/2*cos(th) + r*mn*sin(th), r*mn*cos(th) + r/2*sin(th), 
      r/2*cos(th) + r*mn*sin(th), r*mn*cos(th) - r/2*sin(th));
  }
  for(int i=0; i<5; i++){
    qq = i/5.0;
    waveLine(lerp(-r,-r/2,qq), lerp(0,-r*mn,qq), lerp(-r/2,r/2,qq), r*mn);
    waveLine(lerp(-r/2,r/2,qq), -r*mn, lerp(r/2,r,qq), lerp(r*mn,0,qq));
  }
}

color YELLA = #FFCE00, CYAN = #4FDBFF, MAGENTA = #F012BE;
PImage f1, f2;

void draw_() {
  background(250);
  push();
  translate(width/2, height/2);
  
  background(250);
  stroke(CYAN);
  wavePhase = 0;
  hexx();
  f1 = get();
  
  background(250);
  stroke(MAGENTA);
  wavePhase = TWO_PI/3;
  hexx();
  f2 = get();
  
  background(250);
  stroke(YELLA);
  wavePhase = 2*TWO_PI/3;
  hexx();
  
  pop();
  
  blend(f1,0,0,width,height,0,0,width,height,MULTIPLY);
  blend(f2,0,0,width,height,0,0,width,height,MULTIPLY);
}