colour cubes

colourCubes.pde

// by dave @beesandbombs

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 480;        
float shutterAngle = .5;

boolean recording = false;

void setup() {
  size(720, 720, P3D);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  noStroke();
  colorMode(HSB,1);
}

float x, y, z, tt;
int N = 12;
float r = 48, d = 13, aa;

void boxx(float q){
  rotateY(HALF_PI*((12*q)%1));
  for(int i=0; i<4; i++){
    fill((5*(i+int(12*q))/12.0)%1,1,1);
    push();
    rotateY(-HALF_PI*i);
    translate(0,0,d/2);
    rect(0,0,d,d);
    pop();
  }
  for(int i=0; i<2; i++){
    fill(.05);
    push();
    rotateX(HALF_PI+PI*i);
    translate(0,0,d/2);
    rect(0,0,d,d);
    pop();
  }
}

void draw_() {
  background(.05); 
  push();
  translate(width/2, height/2);
  for (int a=-16; a<12; a++) {
    aa = a + 6*t;
    push();
    scale(pow(1.5, aa));
    rotate(PI*a/N);
    for (int i=0; i<N; i++) {
      tt = (t + 100 - 0.02*aa)%1;
      push();
      rotate(TWO_PI*i/N);
      translate(r, 0);
      rotate(PI/3);
      boxx(tt);
      pop();
    }
    pop();
  }
  pop();
}

gif: https://twitter.com/beesandbombs/status/902131701022896134