crystal

crystal.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop(){
  popStyle();
  popMatrix();
}

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if(mousePressed)
        println(c);
    draw_();
  }
  
  else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;
  
    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();
  
    saveFrame("t###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 250;        
float shutterAngle = .6;

boolean recording = false;

void setup() {
  size(960,960,P2D);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  stroke(20);
  noFill();
  strokeWeight(3.2);
}

float x, y, z, tt;
int N = 6;
float R = 320, r = 108;

float x(int in){
  return R*cos(TWO_PI*in/N) + r*cos(-TWO_PI*t + TWO_PI*in/2);
}

float y(int in){
  return R*sin(TWO_PI*in/N) + r*sin(-TWO_PI*t + TWO_PI*in/2);
}

int n = 32;

void draw_() {
  background(250); 
  push();
  translate(width/2, height/2);
  scale(-1,1);
  scale(.9);
  for(int i=0; i<N; i++){
    push();
    rotate(TWO_PI*i/N);
    push();
    translate(R,0);
    rotate(-TWO_PI*i/N);
    for(int j=0; j<n; j++){
      arc(0,0,2*r,2*r,TWO_PI*(j-.15)/n,TWO_PI*(j+.15)/n);
    }
    pop();
    pop();
  }
  
  for(int i=0; i<N-1; i++){
    for(int j=i+1; j<N; j++){
      line(x(i),y(i),x(j),y(j));
    }
  }
  pop();
}