spiral spread

spiralSpread.pde

// by dave whyte aka bees&bombs

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 320;        
float shutterAngle = .6;

boolean recording = false;

void setup() {
  size(720, 720, P3D);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  stroke(32);
  noFill();
  strokeWeight(1.2);
}

float R = 270, r, th;
float ss = 4, sw, tw;

float x(float q){
  th = 14*TWO_PI*sqrt(q);
  r = R*sqrt(q);
  return r*cos(th);
}

float y(float q){
  th = 14*TWO_PI*sqrt(q);
  r = R*sqrt(q);
  return r*sin(th);
} 

float h = 1e-5;

float xp(float q){  // derivative of x
  return (x(q+h)-x(q))/h;
}

float yp(float q){
  return (y(q+h)-y(q))/h;
}

float xpn(float q){  // normalized derivative of x B)
  return xp(q)/dist(xp(q),yp(q),0,0);
}


float ypn(float q){
  return yp(q)/dist(xp(q),yp(q),0,0);
}

float qq;

void thing() {
  beginShape();
  for (int i=0; i<N; i++) {
    qq = i/float(N-1);
    ss = map(cos(TWO_PI*t - TWO_PI*qq),1,-1,0,1);
    ss = ease(constrain(2.5*ss-1.5,0,1),4)*6;
    tw = 3200*qq + 3*TWO_PI*t;
    sw = map(ss,0,6,1.5,2.5);
    if(qq >= .95)
      sw *= ease(map(qq,.95,1,1,0));
    strokeWeight(sw);
    vertex(x(qq) + ss*cos(tw)*ypn(qq), y(qq)-ss*cos(tw)*xpn(qq), ss*sin(tw));
  }
  endShape();
}

float x, y, z, tt;
int N = 12000;

void draw_() {
  background(250); 
  push();
  translate(width/2, height/2 - 50);
  rotateX(.7);
  thing();
  pop();
}

gif: https://twitter.com/beesandbombs/status/892748128268337152