spiral

spiral.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

float c01(float g) {
  return constrain(g, 0, 1);
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 90;        
float shutterAngle = 1;

boolean recording = false;

void setup() {
  size(800, 800, P3D);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  stroke(32);
  noFill();
  strokeWeight(2);
}

float x, y, z, tt;
int N = 3600, nt = 24;
float qq, th;
float rm = 350, thm, r;
float ph;

float sw;

float ph(float r_, float th_) {
  return map(sin(9*th)*sin(3*TWO_PI*r_/rm - TWO_PI*t),1,-1,0,1);
}

void draw_() {
  background(250); 
  push();
  translate(width/2, height/2);
  for (int a=0; a<1; a++) {
    beginShape();
    for (int i=0; i<N; i++) {
      qq = i/float(N-1);
      qq = lerp(qq, sqrt(qq), qq);
      th = TWO_PI*qq*nt;
      r = rm*qq;
      
      sw = 1 + 10*ease(ph(r,th));
      sw *= c01(map(cos(TWO_PI*qq),1,-1,0,100));
      strokeWeight(sw);
      
      x = r*cos(th);
      y = r*sin(th);
      vertex(x, y);
    }
    endShape();
  }
  pop();
}