<!---
	NOTE: I am currently running ImageMagick 6.7.7-10 2014-03-06 Q16. Some of these
	concerns no longer exist in later versions of ImageMagick; though, your mileage
	may vary - I've read conflicting testimonials on this matter.
--->

<!--- Setup our ImageMagick arguments. --->
<cfset args = [] />

<!--- Setup our input file. Adding quotes to ensure valid paths. --->
<cfset arrayAppend( args, ( """" & expandPath( "./calm-face.png" ) & """" ) ) />

<!--- Resize the image to a max-width of 200px. --->
<cfset arrayAppend( args, "-resize 200" ) />

<!---
	Define the color-space of the thumbnail to be sRGB. This seems to be the more
	commonly supported color model (though, caveat, I know next to nothing about
	what color spaces even mean!)
--->
<cfset arrayAppend( args, "-colorspace sRGB" ) />

<!---
	For PNG images, sometimes ImageMagick tries to be too clever. It will look at the
	image data, and if it sees that it is all grayscale, it will try to collapse the
	color model down to PNG8. This causes grayscale images to come out far too dark.
	But, if we force ImageMagick to keep the image as PNG24, things will work out
	much better.

	CAUTION: I *think* PNG24 may result in some data-loss with regard to alpha-
	transparency. But, I have not worked too much with transparency and ImageMagick, so
	take that warning with a grain of salt.
	--
	Read More: http://adamish.com/blog/archives/746
--->
<cfset arrayAppend( args, "-define png:format=png24" ) />

<!--- Setup our output file. Adding quotes to ensure valid paths. --->
<cfset arrayAppend( args, ( """" & expandPath( "./thumb.png" ) & """" ) ) />

<!--- Run the convert command. --->
<cfexecute
	variable="result"
	name="convert"
	arguments="#arrayToList( args, ' ' )#"
	timeout="60"
	errorVariable="exeError"
/>