default_settings.diff

diff --git a/ycmd/default_settings.json b/ycmd/default_settings.json
index e8359582..f4e89176 100644
--- a/ycmd/default_settings.json
+++ b/ycmd/default_settings.json
@@ -29,18 +29,18 @@
   "python_binary_path": "",
   "language_server": [],
   "java_jdtls_use_clean_workspace": 1,
-  "java_jdtls_workspace_root_path": "",
+  "java_jdtls_workspace_root_path": "/tmp",
   "java_jdtls_extension_path": [],
   "use_clangd": 1,
-  "clangd_binary_path": "",
+  "clangd_binary_path": "clangd",
   "clangd_args": [],
   "clangd_uses_ycmd_caching": 1,
   "disable_signature_help": 0,
-  "gopls_binary_path": "",
+  "gopls_binary_path": "gopls",
   "gopls_args": [],
-  "rust_toolchain_root": "",
-  "tsserver_binary_path": "",
-  "roslyn_binary_path": "",
-  "mono_binary_path": "",
-  "java_binary_path": ""
+  "rust_toolchain_root": "/usr",
+  "tsserver_binary_path": "tsserver",
+  "roslyn_binary_path": "/opt/omnisharp-roslyn/OmniSharp.exe",
+  "mono_binary_path": "mono",
+  "java_binary_path": "java"
 }

PKGBUILD

# Maintainer: Chih-Hsuan Yen <yan12125@gmail.com>
# Contributor: Alexander 'z33ky' Hirsch <1zeeky@gmail.com>
# The following contributors are from the vim-youcompleteme-git AUR package
# Contributor: Babken Vardanyan <483ken 4tgma1l
# Contributor: stykr
# Contributor: Svenstaro
# Contributor: KaiSforza
# Contributor: Simon Gomizelj <simongmzlj@gmail.com>
# Contributor: Daniel Micay <danielmicay@gmail.com>

pkgname=vim-youcompleteme-core-git
pkgver=r2532.d556a43c
pkgrel=2
pkgdesc='A code-completion engine for Vim'
arch=(i686 x86_64)
url='https://valloric.github.io/YouCompleteMe/'
license=('GPL3')
depends=('vim' 'python>=3.6' 'python-watchdog' 'python-requests'
         'python-bottle' 'python-waitress')
makedepends=('git' 'cmake' 'pybind11')
optdepends=(
  'clang>=11.0: C-family semantic completion'
  'gopls: Go semantic completion'
  'nodejs-tern: JavaScript semantic completion'
  'rust-analyzer: Rust semantic completion'
  'typescript: Typescript semantic completion'
  'python-jedi: Python semantic completion'
  'python-numpydocs: Python semantic completion'
  'python-regex: Better Unicode support'
  'omnisharp-roslyn: C# semantic completion'
  'jdk-openjdk: Java semantic completion')

source=(git+https://github.com/ycm-core/YouCompleteMe.git
        git+https://github.com/ycm-core/ycmd.git)
sha256sums=('SKIP' 'SKIP')

_enable_libclang_completer=OFF
_enable_tern_completer=OFF

pkgver() {
  cd YouCompleteMe
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}


prepare() {
  mkdir -p ycmd_build

  cd YouCompleteMe

  git submodule init third_party/ycmd
  git config submodule.third_party/ycmd.url "$srcdir/ycmd"
  git submodule update

  # Force system headers/libs
  # NOTE: Arch package for pybind11 2.6.0 doesn't ship headers. :facepalm:
  cd cpp
  rm -rf llvm
}

build() {
  cd ycmd_build

  cmake \
    -DUSE_PYTHON2=OFF \
    -DUSE_CLANG_COMPLETER=${_enable_libclang_completer} \
    -DUSE_SYSTEM_LIBCLANG=${_enable_libclang_completer} \
    ../YouCompleteMe/third_party/ycmd/cpp

  make ycm_core
}

package() {
  pkg_ycmd_dir="$pkgdir/usr/share/vim/runtime/third_party/ycmd"

  cd YouCompleteMe
  install -Ddm755 "$pkg_ycmd_dir"

  cp -dr --no-preserve=ownership autoload doc plugin python "$pkgdir/usr/share/vim/runtime"
  cp -dr --no-preserve=ownership third_party/ycmd/{ycmd,ycm_core.so,CORE_VERSION} "$pkg_ycmd_dir"

  if [[ ${_enable_libclang_completer} != "OFF" ]]; then
    install -Ddm755 "$pkg_ycmd_dir/third_party/clang/lib/"
    ln -s /usr/lib/libclang.so "$pkg_ycmd_dir/third_party/clang/lib/libclang.so"
    ln -s /usr/lib/clang "$pkg_ycmd_dir/third_party/clang/lib/clang"
  fi

  if [[ ${_enable_tern_completer} != "OFF" ]]; then
    install -Ddm755 "$pkg_ycmd_dir/third_party/tern_runtime/node_modules/"
    ln -s /usr/lib/node_modules/tern "$pkg_ycmd_dir/third_party/tern_runtime/node_modules/"
  fi

  # Other completers are set up in the default_settings.json

  find "$pkgdir" \( -name .git -or -name 'test*' -or -name 'run_tests.py' \) -exec rm -fr {} +

  python -m compileall -d /usr/share/vim/runtime "$pkgdir/usr/share/vim/runtime"
  python -O -m compileall -d /usr/share/vim/runtime "$pkgdir/usr/share/vim/runtime"
}