xfor: transducing for

xfor.clj

(defmacro xfor
  "Like for except the first expression is omitted. Returns a transducer."
  [[binding & seq-exprs] body]
  (let [rf (gensym 'rf)
        acc (gensym 'acc)
        body
        (reduce (fn [body [expr binding]]
                  (case binding
                    :let `(let ~expr ~body)
                    :when `(if ~expr ~body ~acc)
                    :while `(if ~expr ~body (reduced ~acc))
                    `(reduce (fn [~acc ~binding] ~body) ~acc ~expr))) 
          `(~rf ~acc ~body)
          (partition 2 (rseq (vec seq-exprs))))]
    `(fn [~rf]
       (fn
         ([] (~rf))
         ([~acc] (~rf ~acc))
         ([~acc ~binding] ~body)))))

;; for vs xfor
(time (count (into []
               (xfor [x 
                      y (range 1e3)
                      :when (not= x y)]
                 (* x y))
               (range 1e3))))

(time (count (into []
               (for [x (range 1e3) 
                     y (range 1e3)
                     :when (not= x y)]
                 (* x y)))))