scrum.ink

-> start

=== start ===

Let's begin today's standup.

// This records energy level
How are you feeling today?
+ [Green]
+ [Amber]
+ [Red]
-

+ [Review] -> review
+ [Add a story] -> add -> start

=== add ===

How many points is this story worth?
+ [2 points]
+ [3 points]
+ [5 points]
-

How much creative energy do you think you'll need to finish this?
+ [A bit]
+ [A lot]
-

->->

=== review ===

// this is required because we haven't exited the current instance of review.
// instead we want to count the number of times this point is seen.
// https://github.com/inkle/ink/issues/53
- (saw_review)

Reviewing...

// Debug {saw_review} {review} {TURNS_SINCE(->review)}

+ {saw_review > 1 && !exceeded} [Energy exceeded] -> exceeded
+ [Pick a ticket] So how are we doing on this next story?
    ++ [It's done] Great! -> review
    ++ [It's not yet done]
        Is it still something you want to do today?
        +++ [Yes]
            Do you think you'll be able to finish it today?
            ++++ [Yes] Great, let's move on. -> review
            ++++ [No]
                Maybe we should break it down into smaller stories.
                +++++ [Yes] -> add -> review
                +++++ [No] Okay, I'll leave it. -> review
        +++ [No] I'll move it to the backlog, then. -> review
+ [No tickets] Great!
    Would you like to take some things out of the backlog?
    ++ [Yes] -> take_from_backlog
    ++ [No] -> enjoy_your_day
+ [All tickets seen] Great! Here's your schedule for today. -> enjoy_your_day

=== exceeded ===

Are you sure you'll be able to complete everything?

+ [Yes] Great, let's move on. -> review
+ [No] We should reassess. What can or can't you do? -> prune_aggressively

=== prune_aggressively ===

+ [Not done] Still pruning. -> prune_aggressively
+ [Done and under limit] Great, let's move on. -> review

=== take_from_backlog ===

Pick a random story. Does this look ok?

+ [Yes] -> review
+ [No] -> take_from_backlog

=== enjoy_your_day ===

Enjoy the rest of your day!

-> DONE