asneededfun.md

configure.ac:

# GnuTLS crypto backend
PKG_CHECK_MODULES([gnutls], [gnutls >= 3.0 nettle], [
    CFLAGS_save=$CFLAGS
    CFLAGS="$CFLAGS $gnutls_CFLAGS"
    AC_CHECK_HEADERS([nettle/version.h])
    CFLAGS=$CFLAGS_save

    LDFLAGS_save=$LDFLAGS
    LDFLAGS="$LDFLAGS $gnutls_LIBS"
    AC_CHECK_FUNC([gnutls_pkcs11_privkey_generate3], [enable_pkcs11=yes], [enable_pkcs11=no])
    AS_IF([test "$enable_pkcs11" = yes],
        [AC_DEFINE([ENABLE_PKCS11], [1], [PKCS 11 support available])])

    LDFLAGS=$LDFLAGS_save
])

This generates:

abuild@tengu:/home/abuild/rpmbuild/BUILD/knot-2.1.0> gcc -o conftest -fmessage-length=0 \
   -grecord-gcc-switches -O2 -Wall -D_FORTIFY_SOURCE=2 -fstack-protector -funwind-tables \     
   -fasynchronous-unwind-tables -g -Wall -Werror=format-security -Werror=implicit   \
   -lgnutls -lnettle t.c 
/tmp/cc7IrdFj.o: In function `main':
/home/abuild/rpmbuild/BUILD/knot-2.1.0/t.c:63: undefined reference to `gnutls_pkcs11_privkey_generate3'
collect2: error: ld returned 1 exit status

While reordering the arguments ...:

abuild@tengu:/home/abuild/rpmbuild/BUILD/knot-2.1.0> gcc -o conftest -fmessage-length=0 \
   -grecord-gcc-switches -O2 -Wall -D_FORTIFY_SOURCE=2 -fstack-protector -funwind-tables \     
   -fasynchronous-unwind-tables -g -Wall -Werror=format-security -Werror=implicit   \
   t.c -lgnutls -lnettle

The fix

diff --git a/configure.ac b/configure.ac
index 7ffdf1b..9be9200 100644
--- a/configure.ac
+++ b/configure.ac
@@ -129,13 +129,13 @@ PKG_CHECK_MODULES([gnutls], [gnutls >= 3.0 nettle], [
     AC_CHECK_HEADERS([nettle/version.h])
     CFLAGS=$CFLAGS_save

-    LDFLAGS_save=$LDFLAGS
-    LDFLAGS="$LDFLAGS $gnutls_LIBS"
+    LIBS_save=$LIBS
+    LIBS="$LIBS $gnutls_LIBS"
     AC_CHECK_FUNC([gnutls_pkcs11_privkey_generate3], [enable_pkcs11=yes], [enable_pkcs11=no])
     AS_IF([test "$enable_pkcs11" = yes],
         [AC_DEFINE([ENABLE_PKCS11], [1], [PKCS 11 support available])])

-    LDFLAGS=$LDFLAGS_save
+    LIBS=$LIBS_save
 ])

 # JSON for DNSSEC status storage

Commit message:

Fix configure check for pcks11 on distros with a default to as-needed linking

Pushed into the git, thanks.