aviutlで自動エンコードするスクリプトを作ってみました

encode_aviutl.bat

@echo off
REM AviUtl Controlを使った自動エンコードスクリプト

REM AviUtl: http://spring-fragrance.mints.ne.jp/aviutl/
REM AviUtl Control: http://www.geocities.jp/aji_0/

REM ========================================================================================

REM Aviutlの場所とAUCの場所を指定する。デフォルトはバッチファイルと同じ場所。
set AVIUTL_DIR=%~dp0
set AVIUTL="%AVIUTL_DIR%aviutl.exe"
set AUC_DIR="%AVIUTL_DIR%"

REM 出力プラグインの番号を指定してください
set OUTPUT_PLUGIN=4
REM 出力ディレクトリを指定してください
set OUTPUT_DIR=E:\ikalog\

echo 出力プラグイン %OUTPUT_PLUGIN%

if exist "%OUTPUT_DIR%" (
     echo %OUTPUT_DIR%に出力します
) else (
   echo 元のフォルダに出力します
   set OUTPUT_DIR=%~dp1
)

echo Aviutlを起動しています。

"%AUC_DIR%auc_exec" "%AVIUTL%" > nul
set WINDOW_ID=%ERRORLEVEL%

set COUNT=0

:start
set /a COUNT+=1
IF "%~1"=="" GOTO END
IF NOT "%~x1" == ".avi"  GOTO :shiftprosess

set PATH_NAME=%~dp1
set OUTPUT_NAME=%~n1
set INPUT_FILE="%1"
set OUTPUT_FILE="%OUTPUT_DIR%%OUTPUT_NAME%.mp4"

echo エンコードを開始します ( %COUNT% )
echo 入力ファイル %INPUT_FILE%
echo 出力ファイル %OUTPUT_FILE%

echo ファイルを開いています。
call "%AUC_DIR%auc_open" "%WINDOW_ID%" "%INPUT_FILE%"

echo プラグインで出力します。
call "%AUC_DIR%auc_plugout" "%WINDOW_ID%" "%OUTPUT_PLUGIN%"  "%OUTPUT_FILE%"

echo 出力を待っています。
"%AUC_DIR%\auc_wait" "%WINDOW_ID%"

echo 出力が完了しました。
"%AUC_DIR%\auc_close" "%WINDOW_ID%"
IF EXIST "%OUTPUT_FILE%" (GOTO OUTPUT_FILE_EXIST) ELSE GOTO OUTPUT_FILE_NOT_EXIST

:OUTPUT_FILE_EXIST
ECHO 出力ファイルが見つかりました。入力ファイルを削除します。
del "%INPUT_FILE%"
GOTO shiftprosess

:OUTPUT_FILE_NOT_EXIST
ECHO 出力ファイルが見つかりません。終了します。
GOTO END

:shiftprosess
echo 次のファイルへ移ります。
SHIFT
GOTO start

:END
"%AUC_DIR%\auc_exit" "%WINDOW_ID%"
echo 全 %COUNT% ファイルのエンコードを終了しました
pause