Emergency Health Tracking System

Emergency Health Tracking System.ino

#include <Wire.h>         
#include <LiquidCrystal_I2C.h>
#include <SoftwareSerial.h>
#include <TinyGPS.h>

TinyGPS gps;
SoftwareSerial serialgps(2, 3); //--> GPS
SoftwareSerial mySerial(10, 11); // RX, TX --> GSM
 
LiquidCrystal_I2C lcd(0x3F, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE); 

// Sensor and pins variables
int pulsePin = 0;
int buzzer=5;
int call=6;
int location=7;

volatile int BPM;    
volatile int Signal;
volatile int IBI = 600;
volatile boolean Pulse = false;
volatile boolean QS = false;

void setup(){
  Serial.begin(9600);
  serialgps.begin(9600);
  mySerial.begin(9600);
  Serial.println("Heart Beat Monitoring");
  lcd.begin(16,2);              
  lcd.backlight(); 
  lcd.setCursor(0,0);         
  delay(1000);
  lcd.write("Heart Beat ");
  delay(1000);
  lcd.setCursor(0,1);
  lcd.write("Monitering");
  delay(1000);

  // Sets up to read Pulse Sensor signal every 2mS
  interruptSetup();

  pinMode(buzzer, OUTPUT);
  pinMode(call, INPUT);
  pinMode(location, INPUT);
  digitalWrite(call, HIGH);
  digitalWrite(location, HIGH);
  delay(1000);
}

void loop(){
  
  // If heart beat is found
  if (QS == true) {
    // Print heart rate      
      lcd.clear();
      lcd.write("Heart Beat Rate:");
      lcd.setCursor(0,1);
      lcd.print(BPM);
      Serial.print("Heart Beat Rate: ");            
      Serial.println(BPM);
  
    if(BPM>120)
    {
      for(int i=0; i<3;i++)
      {
      digitalWrite(buzzer,HIGH);
      delay(250);
      digitalWrite(buzzer,LOW);
      delay(250);
      }
      
      if(!(digitalRead(call)))
      {
      Serial.println("Calling...");
      lcd.clear();
      lcd.write("Calling...");
      gsmcall();
      delay(10000);
      }
      
      if(!digitalRead(location))
      {
      Serial.println("Location Tracking...");
      lcd.clear();
      lcd.write("Location Tracking...");
      gpslocation();
      delay(10000);
      }
     }
    // Reset the Quantified Self flag for next time      
    QS = false;                       
   }
    delay(6000);
}

GPS_location.ino

int year;
byte month, day, hour, minute, second, hundredths;
unsigned long chars;
unsigned short sentences, failed_checksum;
float latitude, longitude;
int c;

void gpslocation()
{
Serial.println("==========================");
Serial.println("GPS");
Serial.println("===========================");

while(serialgps.available()) 
{
c = serialgps.read(); 
if(gps.encode(c)) 
{
gps.f_get_position(&latitude, &longitude);
Serial.print("Lat/Long: "); 
Serial.print(latitude,6); 
Serial.print(","); 
Serial.println(longitude,6); 
Serial.println();
gps.stats(&chars, &sentences, &failed_checksum);
  mySerial.println("AT");
  delay(1000);
  mySerial.println("AT+CMGF=1");
  delay(1000);
  mySerial.println("AT+CMGS=\"81290255XX\""); //CHANGE TO DESTINATION NUMBER
  delay(1000);
  mySerial.print("Latitude/Longitude:");
  mySerial.print(latitude,6);
  mySerial.print(",");
  mySerial.print(longitude,6);
  mySerial.write(26);
  delay(10000);
}
}
}

GSM_call.ino

void gsmcall()
{
  Serial.println("Calling through GSM Modem");
//set the data rate for the SoftwareSerial port
  delay(2000);
  mySerial.println("ATD81290255XX;"); // ATD81290255XX; -- watch out here for semicolon at the end!!
  Serial.println("Called ATD81290255XX");
  if (mySerial.available())
  Serial.write(mySerial.read());
}

Interrupt.ino

volatile int rate[10];                    // array to hold last ten IBI values
volatile unsigned long sampleCounter = 0;          // used to determine pulse timing
volatile unsigned long lastBeatTime = 0;           // used to find IBI
volatile int P =512;                      // used to find peak in pulse wave, seeded
volatile int T = 512;                     // used to find trough in pulse wave, seeded
volatile int thresh = 512;                // used to find instant moment of heart beat, seeded
volatile int amp = 100;                   // used to hold amplitude of pulse waveform, seeded
volatile boolean firstBeat = true;        // used to seed rate array so we startup with reasonable BPM
volatile boolean secondBeat = false;      // used to seed rate array so we startup with reasonable BPM


void interruptSetup(){     
  // Initializes Timer2 to throw an interrupt every 2mS.
  TCCR2A = 0x02;     // DISABLE PWM ON DIGITAL PINS 3 AND 11, AND GO INTO CTC MODE
  TCCR2B = 0x06;     // DON'T FORCE COMPARE, 256 PRESCALER 
  OCR2A = 0X7C;      // SET THE TOP OF THE COUNT TO 124 FOR 500Hz SAMPLE RATE
  TIMSK2 = 0x02;     // ENABLE INTERRUPT ON MATCH BETWEEN TIMER2 AND OCR2A
  sei();             // MAKE SURE GLOBAL INTERRUPTS ARE ENABLED      
} 


// THIS IS THE TIMER 2 INTERRUPT SERVICE ROUTINE. 
// Timer 2 makes sure that we take a reading every 2 miliseconds
ISR(TIMER2_COMPA_vect){                         // triggered when Timer2 counts to 124
  cli();                                      // disable interrupts while we do this
  Signal = analogRead(pulsePin);              // read the Pulse Sensor 
  sampleCounter += 2;                         // keep track of the time in mS with this variable
  int N = sampleCounter - lastBeatTime;       // monitor the time since the last beat to avoid noise

    //  find the peak and trough of the pulse wave
  if(Signal < thresh && N > (IBI/5)*3){       // avoid dichrotic noise by waiting 3/5 of last IBI
    if (Signal < T){                        // T is the trough
      T = Signal;                         // keep track of lowest point in pulse wave 
    }
  }

  if(Signal > thresh && Signal > P){          // thresh condition helps avoid noise
    P = Signal;                             // P is the peak
  }                                        // keep track of highest point in pulse wave

  //  NOW IT'S TIME TO LOOK FOR THE HEART BEAT
  // signal surges up in value every time there is a pulse
  if (N > 250){                                   // avoid high frequency noise
    if ( (Signal > thresh) && (Pulse == false) && (N > (IBI/5)*3) ){        
      Pulse = true;                               // set the Pulse flag when we think there is a pulse

      IBI = sampleCounter - lastBeatTime;         // measure time between beats in mS
      lastBeatTime = sampleCounter;               // keep track of time for next pulse

      if(secondBeat){                        // if this is the second beat, if secondBeat == TRUE
        secondBeat = false;                  // clear secondBeat flag
        for(int i=0; i<=9; i++){             // seed the running total to get a realisitic BPM at startup
          rate[i] = IBI;                      
        }
      }

      if(firstBeat){                         // if it's the first time we found a beat, if firstBeat == TRUE
        firstBeat = false;                   // clear firstBeat flag
        secondBeat = true;                   // set the second beat flag
        sei();                               // enable interrupts again
        return;                              // IBI value is unreliable so discard it
      }   


      // keep a running total of the last 10 IBI values
      word runningTotal = 0;                  // clear the runningTotal variable    

      for(int i=0; i<=8; i++){                // shift data in the rate array
        rate[i] = rate[i+1];                  // and drop the oldest IBI value 
        runningTotal += rate[i];              // add up the 9 oldest IBI values
      }

      rate[9] = IBI;                          // add the latest IBI to the rate array
      runningTotal += rate[9];                // add the latest IBI to runningTotal
      runningTotal /= 10;                     // average the last 10 IBI values 
      BPM = 60000/runningTotal;               // how many beats can fit into a minute? that's BPM!
      QS = true;                              // set Quantified Self flag 
      // QS FLAG IS NOT CLEARED INSIDE THIS ISR
    }                       
  }

  if (Signal < thresh && Pulse == true){   // when the values are going down, the beat is over
    Pulse = false;                         // reset the Pulse flag so we can do it again
    amp = P - T;                           // get amplitude of the pulse wave
    thresh = amp/2 + T;                    // set thresh at 50% of the amplitude
    P = thresh;                            // reset these for next time
    T = thresh;
  }

  if (N > 2500){                           // if 2.5 seconds go by without a beat
    thresh = 512;                          // set thresh default
    P = 512;                               // set P default
    T = 512;                               // set T default
    lastBeatTime = sampleCounter;          // bring the lastBeatTime up to date        
    firstBeat = true;                      // set these to avoid noise
    secondBeat = false;                    // when we get the heartbeat back
  }

  sei();                                   // enable interrupts when youre done!
}// end isr